X-Git-Url: http://j8takagi.net/cgi-bin/gitweb.cgi?a=blobdiff_plain;ds=sidebyside;f=as%2Fcasl2lib%2Fl2str2.casl;fp=as%2Fcasl2lib%2Fl2str2.casl;h=65dc7bed9a58d6a2deb9bd70346a18c1073d78ab;hb=886b03134f0e5aad0ed3c29ae8d4e7cfa785f808;hp=0000000000000000000000000000000000000000;hpb=8993a52e06e3f33aad16c8bb842f62307cae8063;p=YACASL2.git

diff --git a/as/casl2lib/l2str2.casl b/as/casl2lib/l2str2.casl
new file mode 100644
index 0000000..65dc7be
--- /dev/null
+++ b/as/casl2lib/l2str2.casl
@@ -0,0 +1,41 @@
+;;; GR1に格納された値を文字列に変換してメモリに格納。
+;;; GR2に文字列の先頭アドレス、GR3に文字列の長さを返す
+;;; 依存プログラム: DIVL, REV
+L2STR   START
+        PUSH    0,GR1
+        PUSH    0,GR4
+        XOR     GR0,GR0         ; GR0 <- 0
+        LD      GR4,GR2         ; GR4 <- GR2
+        AND     GR1,GR1         ; GR1をテスト
+        JZE     ZERO            ; GR1が0の場合、ZEROにジャンプ
+        PUSH    0,GR2
+STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
+        JMI     STLST           ; ↓
+        LAD     GR2,10          ; GR2に10進数の「10」を格納。
+        CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
+        LD      GR1,GR3         ; GR1にGR3をコピー
+        LD      GR1,NCHAR,GR1   ; GR1を文字に変換
+        ST      GR1,0,GR4       ; (GR4) <- GR1
+        LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
+        LD      GR1,GR0         ; GR0をGR1にコピー
+        JUMP    STI             ; ループ終端
+STLST   POP     GR2
+        LD      GR1,NCHAR,GR1   ; GR1を文字に変換
+        ST      GR1,0,GR4       ; (GR4) <- GR1
+        LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
+        JUMP    PRT             ; PRTにジャンプ
+ZERO    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
+        ST      GR1,0,GR4       ; ↓ (GR4) <- GR1
+        LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
+PRT     LD      GR1,GR2         ; GR1に文字列のアドレスを格納
+        SUBL    GR4,GR2         ; GR2 <- GR4 - GR2
+        LD      GR2,GR4         ; ↓
+        CALL    REV             ; 文字列を逆順に並べ替え
+        LD      GR3,GR2         ; GR3に文字列の長さを格納
+        LD      GR2,GR4         ; GR2に文字列のアドレスを格納
+        POP     GR4
+        POP     GR1
+        RET
+LEN     DS      1
+NCHAR   DC      '0123456789'
+        END