as/FUNC/outa.casl

   1 ;;; GR1に格納された値を、10進数の整数値（-32768〜32767）として表示
   2 OUTA    START
   3         RPUSH
   4         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         LAD     GR4,0           ; 負数フラグ。GR1が負数の場合、GR4は1
   7         ST      GR0,LEN         ; LENの初期化
   8         AND     GR1,GR1         ; GR1をテスト
   9         JZE     ZPRT            ; GR1が0の場合、ZPRTにジャンプ
  10         JPL     STI             ; GR1が正数の場合、STIにジャンプ
  11         LAD     GR4,1           ; GR1が負数の場合、GR4をオン
  12         CALL    OABS            ;                  GR1を正数に変換
  13 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  14         JMI     STLST           ; ↓
  15         CALL    ODIVL           ; GR1とGR2の、商をGR0、剰余をGR3に格納
  16         LD      GR1,GR3         ; GR1にGR3をコピー
  17         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  18         CALL    STSTR           ; GR1をSTR領域に格納
  19         LD      GR1,GR0         ; GR0をGR1にコピー
  20         JUMP    STI             ; ループ終端
  21 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  22         CALL    STSTR           ; GR1をSTR領域に格納
  23         AND     GR4,GR4         ; 正数の場合
  24         JZE     PRT             ; ↓
  25         LD      GR1,='-'        ; 負数の場合、「-」をSTR領域に格納
  26         CALL    STSTR           ; ↓
  27         JUMP    PRT             ; PRTにジャンプ
  28 ZPRT    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  29         CALL    STSTR           ; ↓
  30 PRT     LD      GR2,LEN         ; GR2にLENの値を格納
  31         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  32         CALL    REV             ; 文字列を逆順に並べ替え
  33         OUT     STR,LEN         ; 文字列を出力
  34         RPOP
  35         RET
  36 STR     DS      17
  37 LEN     DS      1
  38 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  39         END
  40 ;; GR1をSTR領域に格納し、LENをインクリメント
  41 STSTR   START
  42         PUSH    0,GR1
  43         PUSH    0,GR2
  44         LD      GR2,LEN         ; GR2にLENの値をロード
  45         ST      GR1,STR,GR2     ; STR+GR2 <- GR1
  46         LAD     GR2,1,GR2       ; GR2 <- GR2 + 1
  47         ST      GR2,LEN         ; LENにGR2を格納
  48         POP     GR2
  49         POP     GR1
  50         RET
  51         END
  52 ;;; GR1の値とGR2の値の、商をGR0、剰余をGR3に格納する
  53 ;;; 0〜65535の範囲の数値を扱う
  54 ODIVL   START
  55         PUSH    0,GR1
  56         PUSH    0,GR2
  57         PUSH    0,GR4
  58         AND     GR2,GR2         ; GR2が0の場合、ODFINへジャンプ
  59         JZE     ODFIN           ; ↓
  60         ST      GR2,ODY         ; ODYにGR2の初期値を保存
  61         LAD     GR0,0           ; GR0の初期化
  62         LAD     GR3,0           ; GR3の初期化
  63         LAD     GR4,1           ; GR4の初期化。対象ビットを表す
  64 ODSL    CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、ODLOOPへループ脱出
  65         JPL     ODLOOP          ; ↓
  66         SLL     GR4,1           ; GR4を1回左シフト
  67         SLL     GR2,1           ; GR2を1回左シフト
  68         JOV     ODYOV           ; オーバーフローの場合は、ODYOVにジャンプ
  69         JUMP    ODSL            ; ループ終端
  70 ODYOV   SRL     GR2,1
  71         LAD     GR2,#8000,GR2
  72         SRL     GR4,1
  73         JUMP    ODLPIN
  74 ODLOOP  SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  75         JZE     ODFIN           ; (GR4 = 0)の場合、ループ脱出
  76         SRL     GR2,1           ; GR2を1回右シフト
  77         CPL     GR1,ODY         ; (GR1 < ODY)の場合、ループ脱出
  78         JMI     ODFIN           ; ↓
  79         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  80         JMI     ODLOOP          ; ↓
  81 ODLPIN  SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  82         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  83         JUMP    ODLOOP          ; ループ終端
  84 ODFIN   LD      GR3,GR1
  85         POP     GR4
  86         POP     GR2
  87         POP     GR1
  88         RET
  89 ODY     DS      1
  90         END
  91 ;; アドレスがGR1、長さがGR2の文字列を逆順に並べ替える
  92 ;; 例: 12345 -> 54321、54321- -> -12345
  93 REV     START
  94         RPUSH
  95         LAD     GR3,0           ; GR3の初期化
  96 RPU     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  97         JZE     RNEXT           ; ↓
  98         LD      GR4,GR1         ; GR4にGR1の値をコピー
  99         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 100         LD      GR5,0,GR4       ; GR5にアドレスGR4の値を格納
 101         PUSH    0,GR5           ; GR5をプッシュ
 102         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 103         JUMP    RPU             ; ループ終端
 104 RNEXT   LAD     GR3,0           ; GR3の初期化
 105 RPO     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 106         JZE     RFIN            ; ↓
 107         POP     GR5             ; GR5にポップ
 108         LD      GR4,GR1         ; GR4にGR1の値をコピー
 109         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 110         ST      GR5,0,GR4       ; アドレスGR4にGR5の値を格納
 111         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 112         JUMP    RPO             ; ループ終端
 113 RFIN    RPOP
 114         RET
 115         END
 116 ;; GR1の値を絶対値に変換する。GR1にはマイナスの数値が格納されていると想定。
 117 ;; 例: -10 -> 10, -20 -> 20
 118 OABS    START
 119         XOR     GR1,=#FFFF      ; GR1の値を反転
 120         LAD     GR1,1,GR1       ; GR1 <- GR1 + 1
 121         RET
 122         END