as/FUNC/outl.casl

   1 ;;; GR1に格納された値を、10進数の整数値（0〜65535）として表示
   2 OUTL    START
   3         RPUSH
   4         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         ST      GR0,LEN         ; LENの初期化
   7         AND     GR1,GR1         ; GR1をテスト
   8         JZE     ZPRT            ; GR1が0の場合、ZPRTにジャンプ
   9 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  10         JMI     STLST           ; ↓
  11         CALL    ODIVL           ; GR1とGR2の、商をGR0、剰余をGR3に格納
  12         LD      GR1,GR3         ; GR1にGR3をコピー
  13         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  14         CALL    STSTR           ; GR1をSTR領域に格納
  15         LD      GR1,GR0         ; GR0をGR1にコピー
  16         JUMP    STI             ; ループ終端
  17 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  18         CALL    STSTR           ; GR1をSTR領域に格納
  19         JUMP    PRT             ; PRTにジャンプ
  20 ZPRT    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  21         CALL    STSTR           ; ↓
  22 PRT     LD      GR2,LEN         ; GR2にLENの値を格納
  23         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  24         CALL    REV             ; 文字列を逆順に並べ替え
  25         OUT     STR,LEN         ; 文字列を出力
  26         RPOP
  27         RET
  28 STR     DS      17
  29 LEN     DS      1
  30 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  31         END
  32 ;; GR1をSTR領域に格納し、LENをインクリメント
  33 STSTR   START
  34         PUSH    0,GR1
  35         PUSH    0,GR2
  36         LD      GR2,LEN         ; GR2にLENの値をロード
  37         ST      GR1,STR,GR2     ; STR+GR2 <- GR1
  38         LAD     GR2,1,GR2       ; GR2 <- GR2 + 1
  39         ST      GR2,LEN         ; LENにGR2を格納
  40         POP     GR2
  41         POP     GR1
  42         RET
  43         END
  44 ;;; GR1の値とGR2の値の、商をGR0、剰余をGR3に格納する
  45 ;;; 0〜65535の範囲の数値を扱う
  46 ODIVL   START
  47         PUSH    0,GR1
  48         PUSH    0,GR2
  49         PUSH    0,GR4
  50         AND     GR2,GR2         ; GR2が0の場合、ODFINへジャンプ
  51         JZE     ODFIN           ; ↓
  52         ST      GR2,ODY         ; ODYにGR2の初期値を保存
  53         LAD     GR0,0           ; GR0の初期化
  54         LAD     GR3,0           ; GR3の初期化
  55         LAD     GR4,1           ; GR4の初期化。対象ビットを表す
  56 ODSL    CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、ODLOOPへループ脱出
  57         JPL     ODLOOP          ; ↓
  58         SLL     GR4,1           ; GR4を1回左シフト
  59         SLL     GR2,1           ; GR2を1回左シフト
  60         JOV     ODYOV           ; オーバーフローの場合は、ODYOVにジャンプ
  61         JUMP    ODSL            ; ループ終端
  62 ODYOV   SRL     GR2,1
  63         LAD     GR2,#8000,GR2
  64         SRL     GR4,1
  65         JUMP    ODLPIN
  66 ODLOOP  SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  67         JZE     ODFIN           ; (GR4 = 0)の場合、ループ脱出
  68         SRL     GR2,1           ; GR2を1回右シフト
  69         CPL     GR1,ODY         ; (GR1 < ODY)の場合、ループ脱出
  70         JMI     ODFIN           ; ↓
  71         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  72         JMI     ODLOOP          ; ↓
  73 ODLPIN  SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  74         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  75         JUMP    ODLOOP          ; ループ終端
  76 ODFIN   LD      GR3,GR1
  77         POP     GR4
  78         POP     GR2
  79         POP     GR1
  80         RET
  81 ODY     DS      1
  82         END
  83 ;; アドレスがGR1、長さがGR2の文字列を逆順に並べ替える
  84 ;; 例: 12345 -> 54321、54321- -> -12345
  85 REV     START
  86         RPUSH
  87         LAD     GR3,0           ; GR3の初期化
  88 RPU     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  89         JZE     RNEXT           ; ↓
  90         LD      GR4,GR1         ; GR4にGR1の値をコピー
  91         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  92         LD      GR5,0,GR4       ; GR5にアドレスGR4の値を格納
  93         PUSH    0,GR5           ; GR5をプッシュ
  94         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  95         JUMP    RPU             ; ループ終端
  96 RNEXT   LAD     GR3,0           ; GR3の初期化
  97 RPO     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  98         JZE     RFIN            ; ↓
  99         POP     GR5             ; GR5にポップ
 100         LD      GR4,GR1         ; GR4にGR1の値をコピー
 101         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 102         ST      GR5,0,GR4       ; アドレスGR4にGR5の値を格納
 103         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 104         JUMP    RPO             ; ループ終端
 105 RFIN    RPOP
 106         RET
 107         END