as/FUNC/outl.casl

   1 ;;; GR1に格納された値を、10進数の整数値（0〜65535）として表示
   2 OUTL    START
   3         RPUSH
   4         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         XOR     GR4,GR4         ; 整数値の長さ
   7         AND     GR1,GR1         ; GR1をテスト
   8         JZE     ZERO            ; GR1が0の場合、ZEROにジャンプ
   9 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  10         JMI     STLST           ; ↓
  11         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
  12         LD      GR1,GR3         ; GR1にGR3をコピー
  13         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  14         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  15         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  16         LD      GR1,GR0         ; GR0をGR1にコピー
  17         JUMP    STI             ; ループ終端
  18 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  19         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  20         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  21         JUMP    PRT             ; PRTにジャンプ
  22 ZERO    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  23         ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
  24         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  25 PRT     ST      GR4,LEN         ; LEN <- GR4
  26         LD      GR2,LEN         ; GR2にLENの値を格納
  27         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  28         CALL    REV             ; 文字列を逆順に並べ替え
  29         OUT     STR,LEN         ; 文字列を出力
  30         RPOP
  31         RET
  32 STR     DS      17
  33 LEN     DS      1
  34 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  35         END
  36 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  37 ;;; 入力 GR1:被除数 GR2:除数
  38 ;;; 出力 GR0:商 GR3:剰余
  39 ;;; GR2が0の場合は、GR0、GR3とも0になり、オーバーフロー
  40 DIVL    START
  41         PUSH    0,GR1
  42         PUSH    0,GR2
  43         PUSH    0,GR4
  44         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  45         JZE     DIVZERO         ; ↓
  46         ST      GR2,Y           ; YにGR2の初期値を保存
  47         LAD     GR0,0           ; GR0の初期化
  48         LAD     GR3,0           ; GR3の初期化
  49         LAD     GR4,1           ; GR4の初期化。対象ビットを表す
  50 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  51         JPL     LOOP            ; ↓
  52         SLL     GR4,1           ; GR4を1回左シフト
  53         ST      GR2,TMP         ; GR2の値をTMPに退避
  54         SLL     GR2,1           ; GR2を1回左シフト
  55         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  56         JUMP    SL              ; ループ終端
  57 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  58         SRL     GR4,1           ; GR4を1回右シフト
  59         JUMP    LPIN            ; LPINへジャンプ
  60 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  61         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  62         SRL     GR2,1           ; GR2を1回右シフト
  63         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  64         JMI     SETMOD          ; ↓
  65         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  66         JMI     LOOP            ; ↓
  67 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  68         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  69         JUMP    LOOP            ; ループ終端
  70 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  71         SLL     GR3,1           ; ↓
  72         JUMP    FIN             ; FIN へジャンプ
  73 SETMOD  LD      GR3,GR1
  74 FIN     POP     GR4
  75         POP     GR2
  76         POP     GR1
  77         RET
  78 Y       DS      1
  79 TMP     DS      1
  80         END
  81 ;; アドレスがGR1、長さがGR2の文字列を逆順に並べ替える
  82 ;; 例: 12345 -> 54321、54321- -> -12345
  83 REV     START
  84         RPUSH
  85         LAD     GR3,0           ; GR3の初期化
  86 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  87         JZE     NEXT            ; ↓
  88         LD      GR4,GR1         ; GR4にGR1の値をコピー
  89         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  90         LD      GR5,0,GR4       ; GR5にアドレスGR4の値を格納
  91         PUSH    0,GR5           ; GR5をプッシュ
  92         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  93         JUMP    PU              ; ループ終端
  94 NEXT    LAD     GR3,0           ; GR3の初期化
  95 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  96         JZE     FIN             ; ↓
  97         POP     GR5             ; GR5にポップ
  98         LD      GR4,GR1         ; GR4にGR1の値をコピー
  99         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 100         ST      GR5,0,GR4       ; アドレスGR4にGR5の値を格納
 101         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 102         JUMP    PO              ; ループ終端
 103 FIN     RPOP
 104         RET
 105         END