as/FUNC/outl.casl

   1 ;;; GR1に格納された値を、10進数の整数値（0〜65535）として表示
   2 OUTL    START
   3         RPUSH
   4         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         XOR     GR4,GR4         ; 整数値の長さ
   7         AND     GR1,GR1         ; GR1をテスト
   8         JZE     ZERO            ; GR1が0の場合、ZEROにジャンプ
   9 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  10         JMI     STLST           ; ↓
  11         CALL    ODIVL           ; GR1とGR2の、商をGR0、剰余をGR3に格納
  12         LD      GR1,GR3         ; GR1にGR3をコピー
  13         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  14         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  15         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  16         LD      GR1,GR0         ; GR0をGR1にコピー
  17         JUMP    STI             ; ループ終端
  18 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  19         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  20         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  21         JUMP    PRT             ; PRTにジャンプ
  22 ZERO    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  23         ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
  24         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  25 PRT     ST      GR4,LEN         ; LEN <- GR4
  26         LD      GR2,LEN         ; GR2にLENの値を格納
  27         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  28         CALL    REV             ; 文字列を逆順に並べ替え
  29         OUT     STR,LEN         ; 文字列を出力
  30         RPOP
  31         RET
  32 STR     DS      17
  33 LEN     DS      1
  34 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  35         END
  36 ;;; GR1の値とGR2の値の、商をGR0、剰余をGR3に格納する
  37 ;;; 0〜65535の範囲の数値を扱う
  38 ODIVL   START
  39         PUSH    0,GR1
  40         PUSH    0,GR2
  41         PUSH    0,GR4
  42         AND     GR2,GR2         ; GR2が0の場合、ODFINへジャンプ
  43         JZE     ODFIN           ; ↓
  44         ST      GR2,ODY         ; ODYにGR2の初期値を保存
  45         LAD     GR0,0           ; GR0の初期化
  46         LAD     GR3,0           ; GR3の初期化
  47         LAD     GR4,1           ; GR4の初期化。対象ビットを表す
  48 ODSL    CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、ODLOOPへループ脱出
  49         JPL     ODLOOP          ; ↓
  50         SLL     GR4,1           ; GR4を1回左シフト
  51         SLL     GR2,1           ; GR2を1回左シフト
  52         JOV     ODYOV           ; オーバーフローの場合は、ODYOVにジャンプ
  53         JUMP    ODSL            ; ループ終端
  54 ODYOV   SRL     GR2,1
  55         LAD     GR2,#8000,GR2
  56         SRL     GR4,1
  57         JUMP    ODLPIN
  58 ODLOOP  SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  59         JZE     ODFIN           ; (GR4 = 0)の場合、ループ脱出
  60         SRL     GR2,1           ; GR2を1回右シフト
  61         CPL     GR1,ODY         ; (GR1 < ODY)の場合、ループ脱出
  62         JMI     ODFIN           ; ↓
  63         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  64         JMI     ODLOOP          ; ↓
  65 ODLPIN  SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  66         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  67         JUMP    ODLOOP          ; ループ終端
  68 ODFIN   LD      GR3,GR1
  69         POP     GR4
  70         POP     GR2
  71         POP     GR1
  72         RET
  73 ODY     DS      1
  74         END
  75 ;; アドレスがGR1、長さがGR2の文字列を逆順に並べ替える
  76 ;; 例: 12345 -> 54321、54321- -> -12345
  77 REV     START
  78         RPUSH
  79         LAD     GR3,0           ; GR3の初期化
  80 RPU     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  81         JZE     RNEXT           ; ↓
  82         LD      GR4,GR1         ; GR4にGR1の値をコピー
  83         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  84         LD      GR5,0,GR4       ; GR5にアドレスGR4の値を格納
  85         PUSH    0,GR5           ; GR5をプッシュ
  86         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  87         JUMP    RPU             ; ループ終端
  88 RNEXT   LAD     GR3,0           ; GR3の初期化
  89 RPO     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  90         JZE     RFIN            ; ↓
  91         POP     GR5             ; GR5にポップ
  92         LD      GR4,GR1         ; GR4にGR1の値をコピー
  93         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  94         ST      GR5,0,GR4       ; アドレスGR4にGR5の値を格納
  95         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  96         JUMP    RPO             ; ループ終端
  97 RFIN    RPOP
  98         RET
  99         END