as/casl2lib/mula.casl

   1 ;;; -32767〜32767の範囲にある正数のかけ算（筆算方式）を行う
   2 ;;; 入力 GR1:被乗数 GR2:乗数
   3 ;;; 出力 GR0:積
   4 ;;; 被乗数または乗数が-32768の場合は、オーバーフロー
   5 ;;; 積が-32767未満または32767より大きい場合は、GR0は積の下位16ビットになり、オーバーフロー
   6 MULA    START
   7         RPUSH
   8         XOR     GR0,GR0         ; 積
   9         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  10         JZE     FIN             ; ↓
  11         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  12         JZE     FIN             ; ↓
  13         LAD     GR3,1           ; 対象ビット
  14         XOR     GR4,GR4         ; マイナスフラグ
  15 CHK1    AND     GR1,GR1         ; (GR1 > 0)の場合は、CHK2へジャンプ
  16         JPL     CHK2            ; ↓
  17         XOR     GR1,ALLON       ; GR1の正負を反転
  18         ADDA    GR1,ONE         ; ↓
  19         JOV     FIN             ; (GR1 = -32768)の場合は終了
  20         XOR     GR4,ONE         ; GR4 <- 1
  21 CHK2    AND     GR2,GR2         ; (GR1 > 0)の場合は、LOOPへジャンプ
  22         JPL     MUL             ; ↓
  23         XOR     GR2,ALLON       ; GR2の正負を反転
  24         ADDA    GR2,ONE         ; ↓
  25         JOV     FIN             ; (GR2 = -32768)の場合は終了
  26         XOR     GR4,ONE         ; マイナスフラグを反転
  27 MUL     CALL    MULL            ; GR0 <- GR1 * GR2
  28         JOV     FIN
  29         AND     GR0,GR0
  30         JMI     OV
  31 MIN     AND     GR4,GR4         ; マイナスフラグがオフの場合、終了
  32         JZE     FIN             ; ↓
  33         XOR     GR0,ALLON       ; GR1の正負を反転
  34         ADDA    GR0,ONE         ; ↓
  35         JUMP    FIN
  36 OV      ADDL    GR0,=#8000
  37 FIN     RPOP
  38         RET
  39 ONE     DC      1
  40 ALLON   DC      #FFFF
  41         END
  42 ;;; 0〜65535の範囲にある正数のかけ算（筆算方式）を行う
  43 ;;; 入力 GR1:被乗数 GR2:乗数
  44 ;;; 出力 GR0:積
  45 ;;; 積が65535より大きい場合は、GR0は積の下位16ビットになり、オーバーフロー
  46 MULL    START
  47         PUSH    0,GR1
  48         PUSH    0,GR3
  49         XOR     GR0,GR0         ; 積
  50         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  51         JZE     FIN             ; ↓
  52         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  53         JZE     FIN             ; ↓
  54         LAD     GR3,1           ; 対象ビット
  55 LOOP    PUSH    0,GR3           ; ループ先頭。GR2のビット中でGR3が示すビットが0の場合、NEXTへジャンプ
  56         AND     GR3,GR2         ; ↓
  57         POP     GR3             ; ↓
  58         JZE     NEXT            ; ↓
  59         ADDL    GR0,GR1         ; GR0 <- GR0 + GR1
  60         JOV     FIN             ; GR0がオーバーフローした場合、ループ脱出
  61 NEXT    SLL     GR3,1           ; GR3を1回左シフト
  62         AND     GR3,GR3         ; (GR3 = 0)の場合、ループ脱出
  63         JZE     FIN             ; ↓
  64         CPL     GR3,GR2         ; (GR3 > GR2)の場合、ループ脱出
  65         JPL     FIN             ; ↓
  66         SLL     GR1,1           ; GR1を1回左シフト
  67         JOV     FIN             ; GR1がオーバーフローした場合、ループ脱出
  68         JUMP    LOOP            ; ループ終端
  69 FIN     POP     GR3
  70         POP     GR1
  71         RET
  72         END