as/casl2lib/mull.casl

   1 ;;; 0〜65535の範囲にある正数のかけ算（筆算方式）を行う
   2 ;;; 入力 GR1:被乗数 GR2:乗数
   3 ;;; 出力 GR0:積の下位WORD GR3:積の上位WORD
   4 ;;; 積が65535より大きい場合は、オーバーフロー
   5 MULL    START
   6         PUSH    0,GR4
   7         PUSH    0,GR5
   8         XOR     GR0,GR0         ; 積
   9         XOR     GR3,GR3         ; 上位word
  10         XOR     GR5,GR5         ; 上位wordの一時値
  11         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  12         JZE     CHKOV           ; ↓
  13         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  14         JZE     CHKOV           ; ↓
  15         LAD     GR4,1           ; 対象ビット
  16 LOOP    PUSH    0,GR4           ; ループ先頭。GR2のビット中でGR4が示すビットが0の場合、NEXTへジャンプ
  17         AND     GR4,GR2         ; ↓
  18         POP     GR4             ; ↓
  19         JZE     NEXT1           ; ↓
  20         ADDL    GR3,GR5         ; GR3 <- GR3 + GR5
  21         ADDL    GR0,GR1         ; GR0 <- GR0 + GR1
  22         JOV     AHB1            ; GR0がオーバーフローした場合、AHB1へジャンプ
  23         JUMP    NEXT1           ; ↓
  24 AHB1    LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  25 NEXT1   SLL     GR4,1           ; GR4を1回左シフト
  26         JOV     CHKOV           ; ↓
  27         SLL     GR5,1           ; GR5を1回左シフト
  28         CPL     GR4,GR2         ; (GR4 > GR2)の場合、CHKOVへジャンプ
  29         JPL     CHKOV           ; ↓
  30         SLL     GR1,1           ; GR1を1回左シフト
  31         JOV     AHB2            ; GR1がオーバーフローした場合、AHBへジャンプ
  32         JUMP    NEXT2           ; ↓
  33 AHB2    LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  34 NEXT2   JUMP    LOOP            ; ループ終端
  35 CHKOV   AND     GR3,GR3         ; GR3 = 0の場合、終了
  36         JZE     FIN             ; ↓
  37         LAD     GR4,#FFFF       ; GR3 <> 0の場合、オーバーフロー
  38         SLL     GR4,1           ; ↓
  39 FIN     POP     GR5
  40         POP     GR4
  41         RET
  42         END