as/casl2lib/outa.casl

   1 ;;; GR1に格納された値を、10進数の整数値（-32768〜32767）として表示
   2 OUTA    START
   3         RPUSH
   4         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         LAD     GR4,0           ; 負数フラグ。GR1が負数の場合、GR4は1
   7         LAD     GR5,0           ; 整数値の長さ
   8         AND     GR1,GR1         ; GR1をテスト
   9         JZE     ZPRT            ; GR1が0の場合、ZPRTにジャンプ
  10         JPL     STI             ; GR1が正数の場合、STIにジャンプ
  11         LAD     GR4,1           ; GR1が負数の場合、GR4をオン
  12         CALL    ABS             ;                  GR1を正数に変換
  13 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  14         JMI     STLST           ; ↓
  15         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
  16         LD      GR1,GR3         ; GR1にGR3をコピー
  17         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  18         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  19         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  20         LD      GR1,GR0         ; GR0をGR1にコピー
  21         JUMP    STI             ; ループ終端
  22 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  23         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  24         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  25         AND     GR4,GR4         ; 正数の場合
  26         JZE     PRT             ; ↓
  27         LD      GR1,='-'        ; 負数の場合、「-」をSTR領域に格納
  28         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  29         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  30         JUMP    PRT             ; PRTにジャンプ
  31 ZPRT    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  32         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  33         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  34 PRT     ST      GR5,LEN         ; LEN <- GR5
  35         LD      GR2,LEN         ; GR2にLENの値を格納
  36         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  37         CALL    REV             ; 文字列を逆順に並べ替え
  38         OUT     STR,LEN         ; 文字列を出力
  39         RPOP
  40         RET
  41 STR     DS      17
  42 LEN     DS      1
  43 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  44         END
  45 ;;; GR1を符号付き整数とみなし、絶対値に変換
  46 ;;; 入力 GR1: -32768から32767の整数
  47 ;;; 出力 GR1: 入力された整数の絶対値
  48 ;;;       OF: 入力されたGR1が-32768の場合、1
  49 ;;;       SF: 入力されたGR1が負数(-32767〜-1)の場合、1
  50 ABS     START
  51         AND     GR1,GR1         ; GR1が0以上の場合は、FINへジャンプ
  52         JPL     FIN             ; ↓
  53         JZE     FIN             ; ↓
  54         XOR     GR1,ALLON       ; GR1のビットを反転
  55         ADDA    GR1,ONE         ; GR1に1を追加
  56         JOV     FIN             ; 足し算でオーバーフローの場合は、OF:1を保持してFINへジャンプ
  57         CPL     GR1,ALLON       ; SF:1を設定
  58 FIN     RET
  59 ONE     DC      1
  60 ALLON   DC      #FFFF
  61         END
  62 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  63 ;;; 入力 GR1:被除数 GR2:除数
  64 ;;; 出力 GR0:商 GR3:剰余
  65 ;;; (GR2 = 0)の場合、GR0 GR3とも0になり、オーバーフロー
  66 DIVL    START
  67         PUSH    0,GR1
  68         PUSH    0,GR2
  69         PUSH    0,GR4
  70         XOR     GR0,GR0         ; GR0:商 初期化
  71         XOR     GR3,GR3         ; GR3:剰余 初期化
  72         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  73         JZE     DIVZERO         ; ↓
  74         AND     GR1,GR1         ; (GR1 = 0)の場合、FINへジャンプ
  75         JZE     FIN             ; ↓
  76         ST      GR2,Y           ; YにGR2の初期値を保存
  77         LAD     GR4,1           ; GR4:対象ビットのインデックス 初期化
  78 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  79         JPL     LOOP            ; ↓
  80         SLL     GR4,1           ; GR4を1回左シフト
  81         ST      GR2,TMP         ; GR2の値をTMPに退避
  82         SLL     GR2,1           ; GR2を1回左シフト
  83         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  84         JUMP    SL              ; ループ終端
  85 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  86         SRL     GR4,1           ; GR4を1回右シフト
  87         JUMP    LPIN            ; LPINへジャンプ
  88 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  89         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  90         SRL     GR2,1           ; GR2を1回右シフト
  91         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  92         JMI     SETMOD          ; ↓
  93         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  94         JMI     LOOP            ; ↓
  95 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  96         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  97         JUMP    LOOP            ; ループ終端
  98 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  99         SLL     GR3,1           ; ↓
 100         JUMP    FIN             ; FIN へジャンプ
 101 SETMOD  LD      GR3,GR1         ; GR3 <- GR1。剰余の設定
 102 FIN     POP     GR4
 103         POP     GR2
 104         POP     GR1
 105         RET
 106 Y       DS      1
 107 TMP     DS      1
 108         END
 109 ;;; メモリー上にある指定されたアドレス、長さの文字列を逆順に並べ替える
 110 ;;;     例: 12345 -> 54321、54321- -> -12345
 111 ;;; 入力 GR1:文字列のアドレス GR2:文字列の長さ
 112 ;;; 出力 （同上）
 113 REV     START
 114         RPUSH
 115         LAD     GR3,0           ; GR3の初期化
 116 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 117         JZE     NEXT            ; ↓
 118         LD      GR4,GR1         ; GR4 <- GR1
 119         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 120         LD      GR5,0,GR4       ; GR5 <- GR4アドレスの値
 121         PUSH    0,GR5           ; GR5をプッシュ
 122         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 123         JUMP    PU              ; ループ終端
 124 NEXT    LAD     GR3,0           ; GR3の初期化
 125 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 126         JZE     FIN             ; ↓
 127         POP     GR5             ; GR5にポップ
 128         LD      GR4,GR1         ; GR4にGR1の値をコピー
 129         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 130         ST      GR5,0,GR4       ; GR4のアドレス <- GR5の値
 131         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 132         JUMP    PO              ; ループ終端
 133 FIN     RPOP
 134         RET
 135         END