as/casl2lib/outa.casl

   1 ;;; GR1に格納された値を、10進数の整数値（-32768〜32767）として表示
   2 OUTA    START
   3         RPUSH
   4         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         LAD     GR4,0           ; 負数フラグ。GR1が負数の場合、GR4は1
   7         LAD     GR5,0           ; 整数値の長さ
   8         AND     GR1,GR1         ; GR1をテスト
   9         JZE     ZPRT            ; GR1が0の場合、ZPRTにジャンプ
  10         JPL     STI             ; GR1が正数の場合、STIにジャンプ
  11         LAD     GR4,1           ; GR1が負数の場合、GR4をオン
  12         CALL    ABS             ;                  GR1を正数に変換
  13 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  14         JMI     STLST           ; ↓
  15         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
  16         LD      GR1,GR3         ; GR1にGR3をコピー
  17         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  18         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  19         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  20         LD      GR1,GR0         ; GR0をGR1にコピー
  21         JUMP    STI             ; ループ終端
  22 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  23         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  24         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  25         AND     GR4,GR4         ; 正数の場合
  26         JZE     PRT             ; ↓
  27         LD      GR1,='-'        ; 負数の場合、「-」をSTR領域に格納
  28         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  29         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  30         JUMP    PRT             ; PRTにジャンプ
  31 ZPRT    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  32         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  33         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  34 PRT     ST      GR5,LEN         ; LEN <- GR5
  35         LD      GR2,LEN         ; GR2にLENの値を格納
  36         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  37         CALL    REV             ; 文字列を逆順に並べ替え
  38         OUT     STR,LEN         ; 文字列を出力
  39         RPOP
  40         RET
  41 STR     DS      17
  42 LEN     DS      1
  43 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  44         END
  45 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  46 ;;; 入力 GR1:被除数 GR2:除数
  47 ;;; 出力 GR0:商 GR3:剰余
  48 ;;; GR2が0の場合は、GR0、GR3とも0になり、オーバーフロー
  49 DIVL    START
  50         PUSH    0,GR1
  51         PUSH    0,GR2
  52         PUSH    0,GR4
  53         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  54         JZE     DIVZERO         ; ↓
  55         ST      GR2,Y           ; YにGR2の初期値を保存
  56         LAD     GR0,0           ; GR0の初期化
  57         LAD     GR3,0           ; GR3の初期化
  58         LAD     GR4,1           ; GR4の初期化。対象ビットを表す
  59 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  60         JPL     LOOP            ; ↓
  61         SLL     GR4,1           ; GR4を1回左シフト
  62         ST      GR2,TMP         ; GR2の値をTMPに退避
  63         SLL     GR2,1           ; GR2を1回左シフト
  64         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  65         JUMP    SL              ; ループ終端
  66 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  67         SRL     GR4,1           ; GR4を1回右シフト
  68         JUMP    LPIN            ; LPINへジャンプ
  69 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  70         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  71         SRL     GR2,1           ; GR2を1回右シフト
  72         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  73         JMI     SETMOD          ; ↓
  74         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  75         JMI     LOOP            ; ↓
  76 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  77         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  78         JUMP    LOOP            ; ループ終端
  79 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  80         SLL     GR3,1           ; ↓
  81         JUMP    FIN             ; FIN へジャンプ
  82 SETMOD  LD      GR3,GR1
  83 FIN     POP     GR4
  84         POP     GR2
  85         POP     GR1
  86         RET
  87 Y       DS      1
  88 TMP     DS      1
  89         END
  90 ;; アドレスがGR1、長さがGR2の文字列を逆順に並べ替える
  91 ;; 例: 12345 -> 54321、54321- -> -12345
  92 REV     START
  93         RPUSH
  94         LAD     GR3,0           ; GR3の初期化
  95 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  96         JZE     NEXT            ; ↓
  97         LD      GR4,GR1         ; GR4にGR1の値をコピー
  98         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  99         LD      GR5,0,GR4       ; GR5にアドレスGR4の値を格納
 100         PUSH    0,GR5           ; GR5をプッシュ
 101         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 102         JUMP    PU              ; ループ終端
 103 NEXT    LAD     GR3,0           ; GR3の初期化
 104 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 105         JZE     FIN             ; ↓
 106         POP     GR5             ; GR5にポップ
 107         LD      GR4,GR1         ; GR4にGR1の値をコピー
 108         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 109         ST      GR5,0,GR4       ; アドレスGR4にGR5の値を格納
 110         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 111         JUMP    PO              ; ループ終端
 112 FIN     RPOP
 113         RET
 114         END
 115 ;;; GR1を絶対値に変換する
 116 ABS     START
 117         AND     GR1,GR1
 118         JPL     FIN
 119         JZE     FIN
 120         XOR     GR1,=#FFFF
 121         ADDA    GR1,=1
 122 FIN     RET
 123         END