as/casl2lib/outl.casl

   1 ;;; GR1に格納された値を、10進数の整数値（0〜65535）として表示
   2 ;;; 依存プログラム: DIVL, REV
   3 OUTL    START
   4         RPUSH
   5         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   6         XOR     GR0,GR0         ; GR0 <- 0
   7         XOR     GR4,GR4         ; 整数値の長さ
   8         AND     GR1,GR1         ; GR1をテスト
   9         JZE     ZERO            ; GR1が0の場合、ZEROにジャンプ
  10 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  11         JMI     STLST           ; ↓
  12         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
  13         LD      GR1,GR3         ; GR1にGR3をコピー
  14         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  15         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  16         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  17         LD      GR1,GR0         ; GR0をGR1にコピー
  18         JUMP    STI             ; ループ終端
  19 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  20         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  21         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  22         JUMP    PRT             ; PRTにジャンプ
  23 ZERO    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  24         ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
  25         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  26 PRT     ST      GR4,LEN         ; LEN <- GR4
  27         LD      GR2,LEN         ; GR2にLENの値を格納
  28         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  29         CALL    REV             ; 文字列を逆順に並べ替え
  30         OUT     STR,LEN         ; 文字列を出力
  31         RPOP
  32         RET
  33 STR     DS      17              ; 符号付き2進数で表記した場合を想定
  34 LEN     DS      1
  35 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  36         END
  37 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  38 ;;; 入力 GR1:被除数 GR2:除数
  39 ;;; 出力 GR0:商 GR3:剰余
  40 ;;; (GR2 = 0)の場合、GR0 GR3とも0になり、オーバーフロー
  41 DIVL    START
  42         PUSH    0,GR1
  43         PUSH    0,GR2
  44         PUSH    0,GR4
  45         XOR     GR0,GR0         ; GR0:商 初期化
  46         XOR     GR3,GR3         ; GR3:剰余 初期化
  47         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  48         JZE     DIVZERO         ; ↓
  49         AND     GR1,GR1         ; (GR1 = 0)の場合、FINへジャンプ
  50         JZE     FIN             ; ↓
  51         ST      GR2,Y           ; YにGR2の初期値を保存
  52         LAD     GR4,1           ; GR4:対象ビットのインデックス 初期化
  53 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  54         JPL     LOOP            ; ↓
  55         SLL     GR4,1           ; GR4を1回左シフト
  56         ST      GR2,TMP         ; GR2の値をTMPに退避
  57         SLL     GR2,1           ; GR2を1回左シフト
  58         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  59         JUMP    SL              ; ループ終端
  60 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  61         SRL     GR4,1           ; GR4を1回右シフト
  62         JUMP    LPIN            ; LPINへジャンプ
  63 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  64         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  65         SRL     GR2,1           ; GR2を1回右シフト
  66         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  67         JMI     SETMOD          ; ↓
  68         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  69         JMI     LOOP            ; ↓
  70 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  71         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  72         JUMP    LOOP            ; ループ終端
  73 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  74         SLL     GR3,1           ; ↓
  75         JUMP    FIN             ; FIN へジャンプ
  76 SETMOD  LD      GR3,GR1         ; GR3 <- GR1。剰余の設定
  77 FIN     POP     GR4
  78         POP     GR2
  79         POP     GR1
  80         RET
  81 Y       DS      1
  82 TMP     DS      1
  83         END
  84 ;;; メモリー上にある指定されたアドレス、長さの文字列を逆順に並べ替える
  85 ;;;     例: 12345 -> 54321、54321- -> -12345
  86 ;;; 入力 GR1:文字列のアドレス GR2:文字列の長さ
  87 ;;; 出力 （同上）
  88 REV     START
  89         RPUSH
  90         LAD     GR3,0           ; GR3の初期化
  91 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  92         JZE     NEXT            ; ↓
  93         LD      GR4,GR1         ; GR4 <- GR1
  94         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  95         LD      GR5,0,GR4       ; GR5 <- GR4アドレスの値
  96         PUSH    0,GR5           ; GR5をプッシュ
  97         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  98         JUMP    PU              ; ループ終端
  99 NEXT    LAD     GR3,0           ; GR3の初期化
 100 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 101         JZE     FIN             ; ↓
 102         POP     GR5             ; GR5にポップ
 103         LD      GR4,GR1         ; GR4にGR1の値をコピー
 104         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 105         ST      GR5,0,GR4       ; GR4のアドレス <- GR5の値
 106         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 107         JUMP    PO              ; ループ終端
 108 FIN     RPOP
 109         RET
 110         END