as/casl2lib/outl.casl

   1 ;;; GR1に格納された値を、10進数の整数値（0〜65535）として表示
   2 OUTL    START
   3         RPUSH
   4         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         XOR     GR4,GR4         ; 整数値の長さ
   7         AND     GR1,GR1         ; GR1をテスト
   8         JZE     ZERO            ; GR1が0の場合、ZEROにジャンプ
   9 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  10         JMI     STLST           ; ↓
  11         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
  12         LD      GR1,GR3         ; GR1にGR3をコピー
  13         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  14         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  15         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  16         LD      GR1,GR0         ; GR0をGR1にコピー
  17         JUMP    STI             ; ループ終端
  18 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  19         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  20         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  21         JUMP    PRT             ; PRTにジャンプ
  22 ZERO    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  23         ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
  24         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  25 PRT     ST      GR4,LEN         ; LEN <- GR4
  26         LD      GR2,LEN         ; GR2にLENの値を格納
  27         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  28         CALL    REV             ; 文字列を逆順に並べ替え
  29         OUT     STR,LEN         ; 文字列を出力
  30         RPOP
  31         RET
  32 STR     DS      17
  33 LEN     DS      1
  34 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  35         END
  36 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  37 ;;; 入力 GR1:被除数 GR2:除数
  38 ;;; 出力 GR0:商 GR3:剰余
  39 ;;; (GR2 = 0)の場合、GR0 GR3とも0になり、オーバーフロー
  40 DIVL    START
  41         PUSH    0,GR1
  42         PUSH    0,GR2
  43         PUSH    0,GR4
  44         XOR     GR0,GR0         ; GR0:商 初期化
  45         XOR     GR3,GR3         ; GR3:剰余 初期化
  46         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  47         JZE     DIVZERO         ; ↓
  48         AND     GR1,GR1         ; (GR1 = 0)の場合、FINへジャンプ
  49         JZE     FIN             ; ↓
  50         ST      GR2,Y           ; YにGR2の初期値を保存
  51         LAD     GR4,1           ; GR4:対象ビットのインデックス 初期化
  52 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  53         JPL     LOOP            ; ↓
  54         SLL     GR4,1           ; GR4を1回左シフト
  55         ST      GR2,TMP         ; GR2の値をTMPに退避
  56         SLL     GR2,1           ; GR2を1回左シフト
  57         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  58         JUMP    SL              ; ループ終端
  59 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  60         SRL     GR4,1           ; GR4を1回右シフト
  61         JUMP    LPIN            ; LPINへジャンプ
  62 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  63         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  64         SRL     GR2,1           ; GR2を1回右シフト
  65         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  66         JMI     SETMOD          ; ↓
  67         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  68         JMI     LOOP            ; ↓
  69 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  70         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  71         JUMP    LOOP            ; ループ終端
  72 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  73         SLL     GR3,1           ; ↓
  74         JUMP    FIN             ; FIN へジャンプ
  75 SETMOD  LD      GR3,GR1         ; GR3 <- GR1。剰余の設定
  76 FIN     POP     GR4
  77         POP     GR2
  78         POP     GR1
  79         RET
  80 Y       DS      1
  81 TMP     DS      1
  82         END
  83 ;;; メモリー上にある指定されたアドレス、長さの文字列を逆順に並べ替える
  84 ;;;     例: 12345 -> 54321、54321- -> -12345
  85 ;;; 入力 GR1:文字列のアドレス GR2:文字列の長さ
  86 ;;; 出力 （同上）
  87 REV     START
  88         RPUSH
  89         LAD     GR3,0           ; GR3の初期化
  90 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  91         JZE     NEXT            ; ↓
  92         LD      GR4,GR1         ; GR4 <- GR1
  93         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  94         LD      GR5,0,GR4       ; GR5 <- GR4アドレスの値
  95         PUSH    0,GR5           ; GR5をプッシュ
  96         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  97         JUMP    PU              ; ループ終端
  98 NEXT    LAD     GR3,0           ; GR3の初期化
  99 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 100         JZE     FIN             ; ↓
 101         POP     GR5             ; GR5にポップ
 102         LD      GR4,GR1         ; GR4にGR1の値をコピー
 103         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 104         ST      GR5,0,GR4       ; GR4のアドレス <- GR5の値
 105         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 106         JUMP    PO              ; ループ終端
 107 FIN     RPOP
 108         RET
 109         END