as/casl2lib/str2l.casl

   1 ;;; 10進数の整数を表す文字列を数値に変換
   2 ;;; 数値の範囲は、0から65535
   3 ;;; 入力 GR1: 文字列を格納するアドレス
   4 ;;;      GR2: 文字列の長さ。最大5けた
   5 ;;; 出力 GR0: 数値
   6 ;;;           文字列が最大長より大きい場合や数値以外の場合は、GR0は#FFFF、OFは1
   7 ;;; 依存プログラム: MULL
   8 STR2L   START
   9         PUSH    0,GR1
  10         PUSH    0,GR2
  11         PUSH    0,GR3
  12         PUSH    0,GR4
  13         PUSH    0,GR5
  14         XOR     GR0,GR0         ; GR0:初期化
  15         AND     GR2,GR2         ; (GR2 = 0)の場合、FINへジャンプ
  16         JZE     FIN             ; ↓
  17         CPL     GR2,MAXLEN      ; (GR2 > MAXLEN)の場合、LENOVへジャンプ
  18         JPL     LENOV           ; ↓
  19         ST      GR1,STR         ; STR <- GR1 文字列の開始アドレス
  20         ST      GR2,LEN         ; LEN <- GR2
  21         LAD     GR2,10          ; GR2:10進数の「10」
  22         XOR     GR4,GR4         ; GR4:値の一時格納
  23         XOR     GR5,GR5         ; GR5:インデックス
  24 STOL    CPL     GR5,LEN         ; ループ先頭。(GR5 = LEN)の場合、ループ脱出
  25         JZE     CP              ; ↓
  26         LD      GR1,STR         ; GR1に、入力文字列中の次の桁を格納
  27         ADDL    GR1,GR5         ; ↓
  28         LD      GR1,0,GR1       ; ↓
  29         CPL     GR1,ZERO        ; (GR1 < '0')の場合、NANへジャンプ
  30         JMI     NAN             ; ↓
  31         CPL     GR1,NINE        ; (GR1 > '9')の場合、NANへジャンプ
  32         JPL     NAN             ; ↓
  33         SUBL    GR1,ZERO        ; GR1の文字を、対応する数値に変換
  34         ST      GR5,NLEN        ; GR5 <- LEN - NLEN - 1
  35         LD      GR5,LEN         ; ↓
  36         SUBA    GR5,NLEN        ; ↓
  37 MUL10   CPA     GR5,=1          ; ループ先頭。GR1 <- 10 ** GR5
  38         JZE     NEXT            ; (GR5 = 1)の場合、ループ脱出
  39         JMI     NEXT            ; ↓
  40         CALL    MULL            ; MULLを呼び出し、GR0 <- GR1 * GR2
  41         JOV     FIN             ; ↓ オーバーフロー時は、プログラム終端へジャンプ
  42         LD      GR1,GR0         ; GR1 <- GR0
  43         LAD     GR5,-1,GR5      ; GR5 <- GR5 -1
  44         JUMP    MUL10           ; ループ終端へジャンプ
  45 NEXT    LD      GR5,NLEN        ; GR5 <- NLEN。復元
  46         ADDL    GR4,GR1         ; GR4 <- GR4 + GR1
  47         JOV     FIN             ; ↓
  48         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  49         JUMP    STOL            ; ループ終端
  50 NAN     LAD     GR2,#FFFF       ; GR2 <- #FFFF
  51         JUMP    FIN             ; FINへジャンプ
  52 CP      LD      GR1,GR4         ; GR0 <- GR4
  53         LD      GR0,LEN         ; GR0 <- LEN
  54         JUMP    FIN             ; プログラム終端へジャンプ
  55 LENOV   LAD     GR0,#FFFF       ; 文字列が最大長より大きい場合、GR0 <- #FFFF
  56         SRA     GR0,1           ; ↓ オーバーフロー発生
  57 FIN     POP     GR5
  58         POP     GR4
  59         POP     GR3
  60         POP     GR2
  61         POP     GR1
  62         RET
  63 ZERO    DC      '0'
  64 NINE    DC      '9'
  65 MAXLEN  DC      5               ; 文字列の最大長
  66 STR     DS      1
  67 LEN     DS      1
  68 NLEN    DS      1
  69         END
  70 ;;; 0〜65535の範囲にある正数のかけ算（筆算方式）を行う
  71 ;;; 入力 GR1:被乗数 GR2:乗数
  72 ;;; 出力 GR0:積の下位WORD GR3:積の上位WORD
  73 ;;; 積が65535より大きい場合は、オーバーフロー
  74 MULL    START
  75         PUSH    0,GR4
  76         PUSH    0,GR5
  77         XOR     GR0,GR0         ; 積
  78         XOR     GR3,GR3         ; 上位word
  79         XOR     GR5,GR5         ; 上位wordの一時値
  80         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  81         JZE     CHKOV           ; ↓
  82         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  83         JZE     CHKOV           ; ↓
  84         LAD     GR4,1           ; 対象ビット
  85 LOOP    PUSH    0,GR4           ; ループ先頭。GR2のビット中でGR4が示すビットが0の場合、NEXTへジャンプ
  86         AND     GR4,GR2         ; ↓
  87         POP     GR4             ; ↓
  88         JZE     NEXT1           ; ↓
  89         ADDL    GR3,GR5         ; GR3 <- GR3 + GR5
  90         ADDL    GR0,GR1         ; GR0 <- GR0 + GR1
  91         JOV     AHB1            ; GR0がオーバーフローした場合、AHB1へジャンプ
  92         JUMP    NEXT1           ; ↓
  93 AHB1    LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  94 NEXT1   SLL     GR4,1           ; GR4を1回左シフト
  95         JOV     CHKOV           ; ↓
  96         SLL     GR5,1           ; GR5を1回左シフト
  97         CPL     GR4,GR2         ; (GR4 > GR2)の場合、CHKOVへジャンプ
  98         JPL     CHKOV           ; ↓
  99         SLL     GR1,1           ; GR1を1回左シフト
 100         JOV     AHB2            ; GR1がオーバーフローした場合、AHBへジャンプ
 101         JUMP    NEXT2           ; ↓
 102 AHB2    LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
 103 NEXT2   JUMP    LOOP            ; ループ終端
 104 CHKOV   AND     GR3,GR3         ; GR3 = 0の場合、終了
 105         JZE     FIN             ; ↓
 106         LAD     GR4,#FFFF       ; GR3 <> 0の場合、オーバーフロー
 107         SLL     GR4,1           ; ↓
 108 FIN     POP     GR5
 109         POP     GR4
 110         RET
 111         END