;;; GR1に格納された値を、10進数の整数値（0〜65535）として表示
OUTL    START
        RPUSH
        LAD     GR2,10          ; GR2に10進数の「10」を格納。
        LAD     GR0,0           ; GR0 <- 0
        XOR     GR4,GR4         ; 整数値の長さ
        AND     GR1,GR1         ; GR1をテスト
        JZE     ZERO            ; GR1が0の場合、ZEROにジャンプ
STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
        JMI     STLST           ; ↓
        CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
        LD      GR1,GR3         ; GR1にGR3をコピー
        LD      GR1,NCHAR,GR1   ; GR1を文字に変換
        ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
        LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
        LD      GR1,GR0         ; GR0をGR1にコピー
        JUMP    STI             ; ループ終端
STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
        ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
        LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
        JUMP    PRT             ; PRTにジャンプ
ZERO    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
        ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
        LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
PRT     ST      GR4,LEN         ; LEN <- GR4
        LD      GR2,LEN         ; GR2にLENの値を格納
        LAD     GR1,STR         ; GR1に文字列のアドレスを格納
        CALL    REV             ; 文字列を逆順に並べ替え
        OUT     STR,LEN         ; 文字列を出力
        RPOP
        RET
STR     DS      17              ; 符号付き2進数で表記した場合を想定
LEN     DS      1
NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
        END