as/FUNC/outb.casl

   1 ;;; GR1に格納された値を、2進数値として表示
   2 OUTB    START
   3         RPUSH
   4         LAD     GR2,2           ; GR2に2進数の「2」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         XOR     GR4,GR4         ; 2進数値の長さ
   7         AND     GR1,GR1         ; GR1をテスト
   8         JZE     ZERO            ; GR1が0の場合、ZEROにジャンプ
   9 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  10         JMI     STLST           ; ↓
  11         CALL    ODIVL           ; GR1とGR2の、商をGR0、剰余をGR3に格納
  12         LD      GR1,GR3         ; GR1にGR3をコピー
  13         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  14         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  15         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  16         LD      GR1,GR0         ; GR0をGR1にコピー
  17         JUMP    STI             ; ループ終端
  18 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  19         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  20         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  21         JUMP    EMB             ; EMBにジャンプ
  22 ZERO    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  23         ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
  24         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  25 EMB     LD      GR1,NCHAR       ; GR1 <- '0'
  26 EMLOOP  CPA     GR4,DIG         ; ループ先頭。(GR4 = DIG)の場合は、ループ脱出
  27         JZE     PRT             ; ↓
  28         ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
  29         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  30         JUMP    EMLOOP          ; ループ終端
  31 PRT     ST      GR4,LEN         ; LEN <- GR4
  32         LD      GR2,LEN         ; GR2にLENの値を格納
  33         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  34         CALL    REV             ; 文字列を逆順に並べ替え
  35         OUT     STR,LEN         ; 文字列を出力
  36         RPOP
  37         RET
  38 STR     DS      17
  39 LEN     DS      1
  40 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  41 DIG     DC      16
  42         END
  43 ;;; GR1の値とGR2の値の、商をGR0、剰余をGR3に格納する
  44 ;;; 0〜65535の範囲の数値を扱う
  45 ODIVL   START
  46         PUSH    0,GR1
  47         PUSH    0,GR2
  48         PUSH    0,GR4
  49         AND     GR2,GR2         ; GR2が0の場合、ODFINへジャンプ
  50         JZE     ODFIN           ; ↓
  51         ST      GR2,ODY         ; ODYにGR2の初期値を保存
  52         LAD     GR0,0           ; GR0の初期化
  53         LAD     GR3,0           ; GR3の初期化
  54         LAD     GR4,1           ; GR4の初期化。対象ビットを表す
  55 ODSL    CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、ODLOOPへループ脱出
  56         JPL     ODLOOP          ; ↓
  57         SLL     GR4,1           ; GR4を1回左シフト
  58         SLL     GR2,1           ; GR2を1回左シフト
  59         JOV     ODYOV           ; オーバーフローの場合は、ODYOVにジャンプ
  60         JUMP    ODSL            ; ループ終端
  61 ODYOV   SRL     GR2,1
  62         LAD     GR2,#8000,GR2
  63         SRL     GR4,1
  64         JUMP    ODLPIN
  65 ODLOOP  SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  66         JZE     ODFIN           ; (GR4 = 0)の場合、ループ脱出
  67         SRL     GR2,1           ; GR2を1回右シフト
  68         CPL     GR1,ODY         ; (GR1 < ODY)の場合、ループ脱出
  69         JMI     ODFIN           ; ↓
  70         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  71         JMI     ODLOOP          ; ↓
  72 ODLPIN  SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  73         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  74         JUMP    ODLOOP          ; ループ終端
  75 ODFIN   LD      GR3,GR1
  76         POP     GR4
  77         POP     GR2
  78         POP     GR1
  79         RET
  80 ODY     DS      1
  81         END
  82 ;; アドレスがGR1、長さがGR2の文字列を逆順に並べ替える
  83 ;; 例: 12345 -> 54321、54321- -> -12345
  84 REV     START
  85         RPUSH
  86         LAD     GR3,0           ; GR3の初期化
  87 RPU     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  88         JZE     RNEXT           ; ↓
  89         LD      GR4,GR1         ; GR4にGR1の値をコピー
  90         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  91         LD      GR5,0,GR4       ; GR5にアドレスGR4の値を格納
  92         PUSH    0,GR5           ; GR5をプッシュ
  93         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  94         JUMP    RPU             ; ループ終端
  95 RNEXT   LAD     GR3,0           ; GR3の初期化
  96 RPO     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  97         JZE     RFIN            ; ↓
  98         POP     GR5             ; GR5にポップ
  99         LD      GR4,GR1         ; GR4にGR1の値をコピー
 100         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 101         ST      GR5,0,GR4       ; アドレスGR4にGR5の値を格納
 102         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 103         JUMP    RPO             ; ループ終端
 104 RFIN    RPOP
 105         RET
 106         END