as/casl2lib/inl.casl

   1 ;;; *** This file is auto generated from inl_main.casl ../mull.casl of src_inl ***
   2 ;;; 0〜65535の範囲にある整数の入力を受け付ける
   3 ;;; 入力 （SVC）
   4 ;;; 出力 GR1: 入力された数値 GR0: 文字の長さ。入力が数字以外の場合は、#FFFF
   5 ;;;      65536以上の正数が入力された場合はエラー
   6 INL     START
   7         PUSH    0,GR2
   8         PUSH    0,GR3
   9         PUSH    0,GR4
  10         IN      IBUF,ILEN       ; 入力文字列を格納
  11         LD      GR0,ILEN        ; ILEN = 0の場合、FINへジャンプ
  12         JZE     FIN             ; ↓
  13         XOR     GR1,GR1         ; GR1:各桁の数値 初期化
  14         LAD     GR2,10          ; GR2:10進数の「10」 初期化
  15         LAD     GR3,0           ; GR3:値の一時格納 初期化
  16         LAD     GR4,0           ; GR4:インデックス 初期化
  17 STOL    CPL     GR4,ILEN        ; ループ先頭。(GR4 = ILEN)の場合、ループ脱出
  18         JZE     CP              ; ↓
  19         LD      GR1,IBUF,GR4    ; GR1に、入力文字列中の次の桁を格納
  20         CPL     GR1,ZERO        ; (GR1 < '0')の場合、NANへジャンプ
  21         JMI     NAN              ; ↓
  22         CPL     GR1,NINE        ; (GR1 > '9')の場合、NANへジャンプ
  23         JPL     NAN              ; ↓
  24         SUBL    GR1,ZERO        ; GR1の文字を、対応する数値に変換
  25         ST      GR4,NLEN        ; GR4 <- ILEN - NLEN - 1
  26         LD      GR4,ILEN        ; ↓
  27         SUBA    GR4,NLEN        ; ↓
  28 MUL10   CPA     GR4,=1          ; ループ先頭。GR1 <- 10 ** GR4
  29         JZE     NEXT            ; (GR4 = 1)の場合、ループ脱出
  30         JMI     NEXT            ; ↓
  31         CALL    MULL            ; MULLを呼び出し、GR0 <- GR1 * GR2
  32         JOV     FIN             ; ↓
  33         LD      GR1,GR0         ; GR1 <- GR0
  34         LAD     GR4,-1,GR4      ; GR4 <- GR4 -1
  35         JUMP    MUL10           ; ループ終端
  36 NEXT    LD      GR4,NLEN        ; GR4 <- NLEN。復元
  37         ADDL    GR3,GR1         ; GR3 <- GR3 + GR1
  38         JOV     FIN             ; ↓
  39         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  40         JUMP    STOL            ; ループ終端
  41 NAN     LAD     GR0,#FFFF       ; GR0 <- #FFFF
  42         JUMP    FIN             ; FINへジャンプ
  43 CP      LD      GR1,GR3         ; GR0 <- GR3
  44         LD      GR0,ILEN        ; GR0 <- ILEN
  45 FIN     POP     GR4
  46         POP     GR3
  47         POP     GR2
  48         RET
  49 ZERO    DC      '0'
  50 NINE    DC      '9'
  51 IBUF    DS      5
  52 ILEN    DS      1
  53 NLEN    DS      1
  54         END
  55
  56 ;;; 0〜65535の範囲にある正数のかけ算（筆算方式）を行う
  57 ;;; 入力 GR1:被乗数 GR2:乗数
  58 ;;; 出力 GR0:積
  59 ;;; 積が65535より大きい場合は、GR0は積の下位16ビットになり、オーバーフロー
  60 MULL    START
  61         PUSH    0,GR1
  62         PUSH    0,GR3
  63         XOR     GR0,GR0         ; 積
  64         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  65         JZE     FIN             ; ↓
  66         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  67         JZE     FIN             ; ↓
  68         LAD     GR3,1           ; 対象ビット
  69 LOOP    PUSH    0,GR3           ; ループ先頭。GR2のビット中でGR3が示すビットが0の場合、NEXTへジャンプ
  70         AND     GR3,GR2         ; ↓
  71         POP     GR3             ; ↓
  72         JZE     NEXT            ; ↓
  73         ADDL    GR0,GR1         ; GR0 <- GR0 + GR1
  74         JOV     FIN             ; GR0がオーバーフローした場合、ループ脱出
  75 NEXT    SLL     GR3,1           ; GR3を1回左シフト
  76         AND     GR3,GR3         ; (GR3 = 0)の場合、ループ脱出
  77         JZE     FIN             ; ↓
  78         CPL     GR3,GR2         ; (GR3 > GR2)の場合、ループ脱出
  79         JPL     FIN             ; ↓
  80         SLL     GR1,1           ; GR1を1回左シフト
  81         JOV     FIN             ; GR1がオーバーフローした場合、ループ脱出
  82         JUMP    LOOP            ; ループ終端
  83 FIN     POP     GR3
  84         POP     GR1
  85         RET
  86         END