as/casl2lib/l2str.casl

   1 ;;; GR1に格納された符号なし整数を文字列に変換する
   2 ;;; GR2に文字列の先頭アドレス、GR3に文字列の長さを返す
   3 ;;; 依存プログラム: DIVL, REV
   4 L2STR   START
   5         PUSH    0,GR1
   6         PUSH    0,GR4
   7         XOR     GR0,GR0         ; GR0 <- 0
   8         LD      GR4,GR2         ; GR4 <- GR2
   9         AND     GR1,GR1         ; GR1をテスト
  10         JZE     ZERO            ; GR1が0の場合、ZEROにジャンプ
  11         PUSH    0,GR2
  12 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  13         JMI     STLST           ; ↓
  14         LAD     GR2,10          ; GR2に10進数の「10」を格納。
  15         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
  16         LD      GR1,GR3         ; GR1にGR3をコピー
  17         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  18         ST      GR1,0,GR4       ; (GR4) <- GR1
  19         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  20         LD      GR1,GR0         ; GR0をGR1にコピー
  21         JUMP    STI             ; ループ終端
  22 STLST   POP     GR2
  23         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  24         ST      GR1,0,GR4       ; (GR4) <- GR1
  25         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  26         JUMP    PRT             ; PRTにジャンプ
  27 ZERO    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  28         ST      GR1,0,GR4       ; ↓ (GR4) <- GR1
  29         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  30 PRT     LD      GR1,GR2         ; GR1に文字列のアドレスを格納
  31         SUBL    GR4,GR2         ; GR2 <- GR4 - GR2
  32         LD      GR2,GR4         ; ↓
  33         CALL    REV             ; 文字列を逆順に並べ替え
  34         LD      GR3,GR2         ; GR3に文字列の長さを格納
  35         LD      GR2,GR4         ; GR2に文字列のアドレスを格納
  36         POP     GR4
  37         POP     GR1
  38         RET
  39 LEN     DS      1
  40 NCHAR   DC      '0123456789'
  41         END
  42 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  43 ;;; 入力 GR1:被除数 GR2:除数
  44 ;;; 出力 GR0:商 GR3:剰余
  45 ;;; (GR2 = 0)の場合、GR0 GR3とも0になり、オーバーフロー
  46 DIVL    START
  47         PUSH    0,GR1
  48         PUSH    0,GR2
  49         PUSH    0,GR4
  50         XOR     GR0,GR0         ; GR0:商 初期化
  51         XOR     GR3,GR3         ; GR3:剰余 初期化
  52         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  53         JZE     DIVZERO         ; ↓
  54         AND     GR1,GR1         ; (GR1 = 0)の場合、FINへジャンプ
  55         JZE     FIN             ; ↓
  56         ST      GR2,Y           ; YにGR2の初期値を保存
  57         LAD     GR4,1           ; GR4:対象ビットのインデックス 初期化
  58 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  59         JPL     LOOP            ; ↓
  60         SLL     GR4,1           ; GR4を1回左シフト
  61         ST      GR2,TMP         ; GR2の値をTMPに退避
  62         SLL     GR2,1           ; GR2を1回左シフト
  63         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  64         JUMP    SL              ; ループ終端
  65 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  66         SRL     GR4,1           ; GR4を1回右シフト
  67         JUMP    LPIN            ; LPINへジャンプ
  68 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  69         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  70         SRL     GR2,1           ; GR2を1回右シフト
  71         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  72         JMI     SETMOD          ; ↓
  73         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  74         JMI     LOOP            ; ↓
  75 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  76         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  77         JUMP    LOOP            ; ループ終端
  78 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  79         SLL     GR3,1           ; ↓
  80         JUMP    FIN             ; FIN へジャンプ
  81 SETMOD  LD      GR3,GR1         ; GR3 <- GR1。剰余の設定
  82 FIN     POP     GR4
  83         POP     GR2
  84         POP     GR1
  85         RET
  86 Y       DS      1
  87 TMP     DS      1
  88         END
  89 ;;; メモリー上にある指定されたアドレス、長さの文字列を逆順に並べ替える
  90 ;;;     例: 12345 -> 54321、54321- -> -12345
  91 ;;; 入力 GR1:文字列のアドレス GR2:文字列の長さ
  92 ;;; 出力 （同上）
  93 REV     START
  94         RPUSH
  95         LAD     GR3,0           ; GR3の初期化
  96 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  97         JZE     NEXT            ; ↓
  98         LD      GR4,GR1         ; GR4 <- GR1
  99         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 100         LD      GR5,0,GR4       ; GR5 <- GR4アドレスの値
 101         PUSH    0,GR5           ; GR5をプッシュ
 102         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 103         JUMP    PU              ; ループ終端
 104 NEXT    LAD     GR3,0           ; GR3の初期化
 105 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 106         JZE     FIN             ; ↓
 107         POP     GR5             ; GR5にポップ
 108         LD      GR4,GR1         ; GR4にGR1の値をコピー
 109         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 110         ST      GR5,0,GR4       ; GR4のアドレス <- GR5の値
 111         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 112         JUMP    PO              ; ループ終端
 113 FIN     RPOP
 114         RET
 115         END