as/fe_tests/2009_10/Q12/outb.casl

   1 ;;; GR1に格納された値を、2進数値として表示
   2 OUTL    START
   3         RPUSH
   4         LAD     GR2,2           ; GR2に2進数の「2」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         ST      GR0,LEN         ; LENの初期化
   7         AND     GR1,GR1         ; GR1をテスト
   8         JZE     ZINS            ; GR1が0の場合、ZINSにジャンプ
   9 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  10         JMI     STLST           ; ↓
  11         CALL    ODIVL           ; GR1とGR2の、商をGR0、剰余をGR1に格納
  12         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  13         CALL    STSTR           ; GR1をSTR領域に格納
  14         LD      GR1,GR0         ; GR0をGR1にコピー
  15         JUMP    STI             ; ループ終端
  16 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  17         CALL    STSTR           ; GR1をSTR領域に格納
  18         JUMP    EMB             ; EMBにジャンプ
  19 ZINS    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  20         CALL    STSTR           ; ↓
  21 EMB     LD      GR1,NCHAR       ; GR0 <- '0'
  22 EMLOOP  LD      GR2,LEN         ; GR2 <- LEN
  23         CPA     GR2,DIG         ; ループ先頭。(GR2 = DIG)の場合は、ループ脱出
  24         JZE     PRT             ; ↓
  25         CALL    STSTR           ; GR1をSTR領域に格納
  26         JUMP    EMLOOP          ; ループ終端
  27 PRT     LD      GR2,LEN         ; GR2にLENの値を格納
  28         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  29         CALL    REV             ; 文字列を逆順に並べ替え
  30         OUT     STR,LEN         ; 文字列を出力
  31         RPOP
  32         RET
  33 STR     DS      17
  34 LEN     DS      1
  35 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  36 DIG     DC      16
  37         END
  38 ;; GR1をSTR領域に格納し、LENをインクリメント
  39 STSTR   START
  40         PUSH    0,GR1
  41         PUSH    0,GR2
  42         LD      GR2,LEN         ; GR2にLENの値をロード
  43         ST      GR1,STR,GR2     ; STR+GR2 <- GR1
  44         LAD     GR2,1,GR2       ; GR2 <- GR2 + 1
  45         ST      GR2,LEN         ; LENにGR2を格納
  46         POP     GR2
  47         POP     GR1
  48         RET
  49         END
  50 ;;; GR1の値とGR2の値の、商をGR0、剰余をGR1に格納する
  51 ;;; 0〜65535の範囲の数値を扱う
  52 ODIVL   START
  53         PUSH    0,GR2
  54         PUSH    0,GR3
  55         LAD     GR0,0           ; GR0の初期化。商
  56         ST      GR2,ODY         ; DYにGR2の初期値を保存
  57         LAD     GR3,1           ; GR3の初期化。対象ビットを表す
  58 ODSL    CPL     GR2,GR1         ; ループ先頭。(GR3 > GR1)の場合、DLOOPへループ脱出
  59         JPL     ODLOOP          ; ↓
  60         SLL     GR3,1           ; GR3を1回左シフト
  61         SLL     GR2,1           ; GR2を1回左シフト
  62         JOV     ODYOV           ; オーバーフローの場合は、ODYOVにジャンプ
  63         JUMP    ODSL            ; ループ終端
  64 ODYOV   SRL     GR2,1           ; GR2を1回右シフト
  65         LAD     GR2,#8000,GR2   ; GR2 <- GR2 + #8000
  66         SRL     GR3,1           ; GR3を1回右シフト
  67         JUMP    ODLPIN          ; ODLPINへジャンプ
  68 ODLOOP  SRL     GR3,1           ; ループ先頭。GR3を1回右シフト
  69         JZE     ODFIN           ; (GR3= 0)の場合、ループ脱出
  70         SRL     GR2,1           ; GR2を1回右シフト
  71         CPL     GR1,ODY         ; (GR1 < ODY)の場合、ループ脱出
  72         JMI     ODFIN           ; ↓
  73         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  74         JMI     ODLOOP          ; ↓
  75 ODLPIN  SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  76         ADDL    GR0,GR3         ; GR0 <- GR0 + GR3
  77         JUMP    ODLOOP          ; ループ終端
  78 ODFIN   POP     GR3
  79         POP     GR2
  80         RET
  81 ODY     DS      1
  82 ODMB    DC      #8000
  83         END
  84 ;; アドレスがGR1、長さがGR2の文字列を逆順に並べ替える
  85 ;; 例: 12345 -> 54321、54321- -> -12345
  86 REV     START
  87         RPUSH
  88         LAD     GR3,0           ; GR3の初期化
  89 RPU     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  90         JZE     RNEXT           ; ↓
  91         LD      GR4,GR1         ; GR4にGR1の値をコピー
  92         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  93         LD      GR5,0,GR4       ; GR5にアドレスGR4の値を格納
  94         PUSH    0,GR5           ; GR5をプッシュ
  95         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  96         JUMP    RPU             ; ループ終端
  97 RNEXT   LAD     GR3,0           ; GR3の初期化
  98 RPO     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  99         JZE     RFIN            ; ↓
 100         POP     GR5             ; GR5にポップ
 101         LD      GR4,GR1         ; GR4にGR1の値をコピー
 102         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 103         ST      GR5,0,GR4       ; アドレスGR4にGR5の値を格納
 104         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 105         JUMP    RPO             ; ループ終端
 106 RFIN    RPOP
 107         RET
 108         END