as/FUNC/outa.casl

   1 ;;; GR1に格納された値を、10進数の整数値（-32768〜32767）として表示
   2 OUTA    START
   3         RPUSH
   4         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         LAD     GR4,0           ; 負数フラグ。GR1が負数の場合、GR4は1
   7         LAD     GR5,0           ; 整数値の長さ
   8         AND     GR1,GR1         ; GR1をテスト
   9         JZE     ZPRT            ; GR1が0の場合、ZPRTにジャンプ
  10         JPL     STI             ; GR1が正数の場合、STIにジャンプ
  11         LAD     GR4,1           ; GR1が負数の場合、GR4をオン
  12         CALL    OABS            ;                  GR1を正数に変換
  13 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  14         JMI     STLST           ; ↓
  15         CALL    ODIVL           ; GR1とGR2の、商をGR0、剰余をGR3に格納
  16         LD      GR1,GR3         ; GR1にGR3をコピー
  17         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  18         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  19         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  20         LD      GR1,GR0         ; GR0をGR1にコピー
  21         JUMP    STI             ; ループ終端
  22 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  23         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  24         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  25         AND     GR4,GR4         ; 正数の場合
  26         JZE     PRT             ; ↓
  27         LD      GR1,='-'        ; 負数の場合、「-」をSTR領域に格納
  28         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  29         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  30         JUMP    PRT             ; PRTにジャンプ
  31 ZPRT    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  32         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  33         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  34 PRT     ST      GR5,LEN         ; LEN <- GR5
  35         LD      GR2,LEN         ; GR2にLENの値を格納
  36         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  37         CALL    REV             ; 文字列を逆順に並べ替え
  38         OUT     STR,LEN         ; 文字列を出力
  39         RPOP
  40         RET
  41 STR     DS      17
  42 LEN     DS      1
  43 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  44         END
  45 ;;; GR1の値とGR2の値の、商をGR0、剰余をGR3に格納する
  46 ;;; 0〜65535の範囲の数値を扱う
  47 ODIVL   START
  48         PUSH    0,GR1
  49         PUSH    0,GR2
  50         PUSH    0,GR4
  51         AND     GR2,GR2         ; GR2が0の場合、ODFINへジャンプ
  52         JZE     ODFIN           ; ↓
  53         ST      GR2,ODY         ; ODYにGR2の初期値を保存
  54         LAD     GR0,0           ; GR0の初期化
  55         LAD     GR3,0           ; GR3の初期化
  56         LAD     GR4,1           ; GR4の初期化。対象ビットを表す
  57 ODSL    CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、ODLOOPへループ脱出
  58         JPL     ODLOOP          ; ↓
  59         SLL     GR4,1           ; GR4を1回左シフト
  60         SLL     GR2,1           ; GR2を1回左シフト
  61         JOV     ODYOV           ; オーバーフローの場合は、ODYOVにジャンプ
  62         JUMP    ODSL            ; ループ終端
  63 ODYOV   SRL     GR2,1
  64         LAD     GR2,#8000,GR2
  65         SRL     GR4,1
  66         JUMP    ODLPIN
  67 ODLOOP  SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  68         JZE     ODFIN           ; (GR4 = 0)の場合、ループ脱出
  69         SRL     GR2,1           ; GR2を1回右シフト
  70         CPL     GR1,ODY         ; (GR1 < ODY)の場合、ループ脱出
  71         JMI     ODFIN           ; ↓
  72         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  73         JMI     ODLOOP          ; ↓
  74 ODLPIN  SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  75         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  76         JUMP    ODLOOP          ; ループ終端
  77 ODFIN   LD      GR3,GR1
  78         POP     GR4
  79         POP     GR2
  80         POP     GR1
  81         RET
  82 ODY     DS      1
  83         END
  84 ;; アドレスがGR1、長さがGR2の文字列を逆順に並べ替える
  85 ;; 例: 12345 -> 54321、54321- -> -12345
  86 REV     START
  87         RPUSH
  88         LAD     GR3,0           ; GR3の初期化
  89 RPU     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  90         JZE     RNEXT           ; ↓
  91         LD      GR4,GR1         ; GR4にGR1の値をコピー
  92         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  93         LD      GR5,0,GR4       ; GR5にアドレスGR4の値を格納
  94         PUSH    0,GR5           ; GR5をプッシュ
  95         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  96         JUMP    RPU             ; ループ終端
  97 RNEXT   LAD     GR3,0           ; GR3の初期化
  98 RPO     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  99         JZE     RFIN            ; ↓
 100         POP     GR5             ; GR5にポップ
 101         LD      GR4,GR1         ; GR4にGR1の値をコピー
 102         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 103         ST      GR5,0,GR4       ; アドレスGR4にGR5の値を格納
 104         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 105         JUMP    RPO             ; ループ終端
 106 RFIN    RPOP
 107         RET
 108         END
 109 ;; GR1の値を絶対値に変換する。GR1にはマイナスの数値が格納されていると想定。
 110 ;; 例: -10 -> 10, -20 -> 20
 111 OABS    START
 112         XOR     GR1,=#FFFF      ; GR1の値を反転
 113         LAD     GR1,1,GR1       ; GR1 <- GR1 + 1
 114         RET
 115         END