as/FUNC/outa0.casl

   1 ;;; GR1に格納された値を、10進数の整数値（-32768〜32767）として表示
   2 OUTA    START
   3         RPUSH
   4         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         LAD     GR4,0           ; 負数フラグ。GR1が負数の場合、GR4は1
   7         ST      GR0,LEN         ; LENの初期化
   8         AND     GR1,GR1         ; GR1をテスト
   9         JZE     ZPRT            ; GR1が0の場合、ZPRTにジャンプ
  10         JPL     STI             ; GR1が正数の場合、STIにジャンプ
  11         LAD     GR4,1           ; GR1が負数の場合、GR4をオン
  12         CALL    OABS            ;                  GR1を正数に変換
  13 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  14         JMI     STLST           ; ↓
  15         CALL    ODIVL           ; GR1とGR2の、商をGR0、剰余をGR3に格納
  16         LD      GR1,GR3         ; GR1にGR3をコピー
  17         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  18         CALL    STSTR           ; GR1をSTR領域に格納
  19         LD      GR1,GR0         ; GR0をGR1にコピー
  20         JUMP    STI             ; ループ終端
  21 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  22         CALL    STSTR           ; GR1をSTR領域に格納
  23         AND     GR4,GR4         ; 正数の場合
  24         JZE     PRT             ; ↓
  25         LD      GR1,='-'        ; 負数の場合、「-」をSTR領域に格納
  26         CALL    STSTR           ; ↓
  27         JUMP    PRT             ; PRTにジャンプ
  28 ZPRT    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  29         CALL    STSTR           ; ↓
  30 PRT     LD      GR2,LEN         ; GR2にLENの値を格納
  31         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  32         CALL    REV             ; 文字列を逆順に並べ替え
  33         OUT     STR,LEN         ; 文字列を出力
  34         RPOP
  35         RET
  36 STR     DS      17
  37 LEN     DS      1
  38 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  39         END
  40 ;; GR1をSTR領域に格納し、LENをインクリメント
  41 STSTR   START
  42         PUSH    0,GR1
  43         PUSH    0,GR2
  44         LD      GR2,LEN         ; GR2にLENの値をロード
  45         ST      GR1,STR,GR2     ; STR+GR2 <- GR1
  46         LAD     GR2,1,GR2       ; GR2 <- GR2 + 1
  47         ST      GR2,LEN         ; LENにGR2を格納
  48         POP     GR2
  49         POP     GR1
  50         RET
  51         END
  52 ;;; GR1の値とGR2の値の、商をGR0、剰余をGR3に格納する
  53 ;;; 0〜65535の範囲の数値を扱う
  54 ODIVL   START
  55         PUSH    0,GR1
  56         AND     GR2,GR2         ; (GR2 = 0)の場合、ODYZへジャンプ
  57         JZE     ODYZ            ; ↓
  58         LAD     GR0,0           ; GR0を初期化
  59         LD      GR3,GR1         ; GR3 <- GR1
  60 ODLOOP  CPL     GR3,GR2         ; ループ先頭。(GR3 < GR2)の場合、終了
  61         JMI     ODFIN           ; ↓
  62         SUBL    GR3,GR2         ; GR3 <- GR3 - GR2
  63         ADDL    GR0,ODONE       ; ↓
  64         JUMP    ODLOOP          ; ループ終端
  65 ODYZ    LAD     GR3,#FFFF       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  66         ADDL    GR3,=1          ; ↓
  67         JUMP    ODFIN           ; ODFINへジャンプ
  68 ODFIN   POP     GR1
  69         RET
  70 ODONE   DC      1
  71         END
  72 ;; アドレスがGR1、長さがGR2の文字列を逆順に並べ替える
  73 ;; 例: 12345 -> 54321、54321- -> -12345
  74 REV     START
  75         RPUSH
  76         LAD     GR3,0           ; GR3の初期化
  77 RPU     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  78         JZE     RNEXT           ; ↓
  79         LD      GR4,GR1         ; GR4にGR1の値をコピー
  80         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  81         LD      GR5,0,GR4       ; GR5にアドレスGR4の値を格納
  82         PUSH    0,GR5           ; GR5をプッシュ
  83         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  84         JUMP    RPU             ; ループ終端
  85 RNEXT   LAD     GR3,0           ; GR3の初期化
  86 RPO     CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  87         JZE     RFIN            ; ↓
  88         POP     GR5             ; GR5にポップ
  89         LD      GR4,GR1         ; GR4にGR1の値をコピー
  90         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  91         ST      GR5,0,GR4       ; アドレスGR4にGR5の値を格納
  92         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  93         JUMP    RPO             ; ループ終端
  94 RFIN    RPOP
  95         RET
  96         END
  97 ;; GR1の値を絶対値に変換する。GR1にはマイナスの数値が格納されていると想定。
  98 ;; 例: -10 -> 10, -20 -> 20
  99 OABS    START
 100         XOR     GR1,=#FFFF      ; GR1の値を反転
 101         LAD     GR1,1,GR1       ; GR1 <- GR1 + 1
 102         RET
 103         END