as/casl2lib/diva.casl

   1 ;;; 符号付き整数の割算を筆算方式で行う
   2 ;;; 入力 GR1:被除数 GR2:除数
   3 ;;; 出力 GR0:商 GR3:剰余
   4 ;;; 次の場合はオーバーフロー
   5 ;;;     GR1 = -32768; GR2 = -32768; GR2 = 0
   6 ;;;
   7 DIVA    START
   8         PUSH    0,GR1
   9         PUSH    0,GR2
  10         PUSH    0,GR4
  11         XOR     GR0,GR0         ; 商を初期化
  12         XOR     GR4,GR4         ; マイナスフラグを初期化
  13 CHK1    AND     GR1,GR1         ; (GR1 > 0)の場合は、CHK2へジャンプ
  14         JPL     CHK2            ; ↓
  15         XOR     GR1,ALLON       ; GR1の正負を反転
  16         ADDA    GR1,ONE         ; ↓
  17         JOV     FIN             ; (GR1 = -32768)の場合は終了
  18         XOR     GR4,ONE         ; GR4 <- 1
  19 CHK2    AND     GR2,GR2         ; (GR1 > 0)の場合は、DIVへジャンプ
  20         JPL     DIV             ; ↓
  21         XOR     GR2,ALLON       ; GR2の正負を反転
  22         ADDA    GR2,ONE         ; ↓
  23         JOV     FIN             ; (GR2 = -32768)の場合は終了
  24         XOR     GR4,ONE         ; マイナスフラグを反転
  25 DIV     CALL    DIVL            ; GR0 <- GR1 / GR2; GR3 <- GR1 mod GR2
  26         JOV     FIN             ; (GR2 = 0)の場合は終了
  27 MIN     AND     GR4,GR4         ; マイナスフラグがオフの場合、終了
  28         JZE     FIN             ; ↓
  29         XOR     GR0,ALLON       ; GR1の正負を反転
  30         ADDA    GR0,ONE         ; ↓
  31         XOR     GR3,ALLON       ; GR3の正負を反転
  32         ADDA    GR3,ONE         ; ↓
  33         JUMP    FIN
  34 OV      ADDL    GR0,=#8000
  35 FIN     POP     GR4
  36         POP     GR2
  37         POP     GR1
  38         RET
  39 ONE     DC      1
  40 ALLON   DC      #FFFF
  41         END
  42 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  43 ;;; 入力 GR1:被除数 GR2:除数
  44 ;;; 出力 GR0:商 GR3:剰余
  45 ;;; (GR2 = 0)の場合、GR0 GR3とも0になり、オーバーフロー
  46 DIVL    START
  47         PUSH    0,GR1
  48         PUSH    0,GR2
  49         PUSH    0,GR4
  50         XOR     GR0,GR0         ; GR0:商 初期化
  51         XOR     GR3,GR3         ; GR3:剰余 初期化
  52         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  53         JZE     DIVZERO         ; ↓
  54         AND     GR1,GR1         ; (GR1 = 0)の場合、FINへジャンプ
  55         JZE     FIN             ; ↓
  56         ST      GR2,Y           ; YにGR2の初期値を保存
  57         LAD     GR4,1           ; GR4:対象ビットのインデックス 初期化
  58 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  59         JPL     LOOP            ; ↓
  60         SLL     GR4,1           ; GR4を1回左シフト
  61         ST      GR2,TMP         ; GR2の値をTMPに退避
  62         SLL     GR2,1           ; GR2を1回左シフト
  63         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  64         JUMP    SL              ; ループ終端
  65 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  66         SRL     GR4,1           ; GR4を1回右シフト
  67         JUMP    LPIN            ; LPINへジャンプ
  68 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  69         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  70         SRL     GR2,1           ; GR2を1回右シフト
  71         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  72         JMI     SETMOD          ; ↓
  73         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  74         JMI     LOOP            ; ↓
  75 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  76         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  77         JUMP    LOOP            ; ループ終端
  78 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  79         SLL     GR3,1           ; ↓
  80         JUMP    FIN             ; FIN へジャンプ
  81 SETMOD  LD      GR3,GR1         ; GR3 <- GR1。剰余の設定
  82 FIN     POP     GR4
  83         POP     GR2
  84         POP     GR1
  85         RET
  86 Y       DS      1
  87 TMP     DS      1
  88         END