as/casl2lib/inl.casl

   1 ;;; 0から65535の範囲にある整数の入力を受け付ける
   2 ;;; 入力 （SVC）
   3 ;;; 出力 GR1: 入力された数値
   4 ;;;      GR0: 文字列の長さ。入力が数字以外の場合は、#FFFF
   5 ;;;      65536以上の正数が入力された場合はエラー
   6 INL     START
   7         IN      IBUF,ILEN       ; 入力文字列を格納
   8         LAD     GR1,IBUF
   9         LD      GR2,ILEN
  10         CPA     GR2,LENMAX
  11         JPL     LENOV
  12         CALL    STR2L
  13         JOV     FIN
  14         LD      GR0,GR2
  15         JUMP    FIN
  16 LENOV   LAD     GR0,#FFFF
  17         SRA     GR0,1
  18 FIN     RET
  19 ILEN    DS      1
  20 LENMAX  DC      5
  21 IBUF    DS      5
  22         END
  23 ;;; 10進数の整数を表す文字列を数値に変換
  24 ;;; 数値の範囲は、0から65535
  25 ;;; 入力 GR1: 文字列を格納するアドレス
  26 ;;;      GR2: 文字列の長さ。最大5けた
  27 ;;; 出力 GR0: 数値
  28 ;;;           文字列が最大長より大きい場合や数値以外の場合は、GR0は#FFFF、OFは1
  29 ;;; 依存プログラム: MULL
  30 STR2L   START
  31         PUSH    0,GR1
  32         PUSH    0,GR2
  33         PUSH    0,GR3
  34         PUSH    0,GR4
  35         PUSH    0,GR5
  36         XOR     GR0,GR0         ; GR0:初期化
  37         AND     GR2,GR2         ; (GR2 = 0)の場合、FINへジャンプ
  38         JZE     FIN             ; ↓
  39         CPL     GR2,MAXLEN      ; (GR2 > MAXLEN)の場合、LENOVへジャンプ
  40         JPL     LENOV           ; ↓
  41         ST      GR1,STR         ; STR <- GR1 文字列の開始アドレス
  42         ST      GR2,LEN         ; LEN <- GR2
  43         LAD     GR2,10          ; GR2:10進数の「10」
  44         XOR     GR4,GR4         ; GR4:値の一時格納
  45         XOR     GR5,GR5         ; GR5:インデックス
  46 STOL    CPL     GR5,LEN         ; ループ先頭。(GR5 = LEN)の場合、ループ脱出
  47         JZE     CP              ; ↓
  48         LD      GR1,STR         ; GR1に、入力文字列中の次の桁を格納
  49         ADDL    GR1,GR5         ; ↓
  50         LD      GR1,0,GR1       ; ↓
  51         CPL     GR1,ZERO        ; (GR1 < '0')の場合、NANへジャンプ
  52         JMI     NAN             ; ↓
  53         CPL     GR1,NINE        ; (GR1 > '9')の場合、NANへジャンプ
  54         JPL     NAN             ; ↓
  55         SUBL    GR1,ZERO        ; GR1の文字を、対応する数値に変換
  56         ST      GR5,NLEN        ; GR5 <- LEN - NLEN - 1
  57         LD      GR5,LEN         ; ↓
  58         SUBA    GR5,NLEN        ; ↓
  59 MUL10   CPA     GR5,=1          ; ループ先頭。GR1 <- 10 ** GR5
  60         JZE     NEXT            ; (GR5 = 1)の場合、ループ脱出
  61         JMI     NEXT            ; ↓
  62         CALL    MULL            ; MULLを呼び出し、GR0 <- GR1 * GR2
  63         JOV     FIN             ; ↓ オーバーフロー時は、プログラム終端へジャンプ
  64         LD      GR1,GR0         ; GR1 <- GR0
  65         LAD     GR5,-1,GR5      ; GR5 <- GR5 -1
  66         JUMP    MUL10           ; ループ終端へジャンプ
  67 NEXT    LD      GR5,NLEN        ; GR5 <- NLEN。復元
  68         ADDL    GR4,GR1         ; GR4 <- GR4 + GR1
  69         JOV     FIN             ; ↓
  70         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  71         JUMP    STOL            ; ループ終端
  72 NAN     LAD     GR2,#FFFF       ; GR2 <- #FFFF
  73         JUMP    FIN             ; FINへジャンプ
  74 CP      LD      GR1,GR4         ; GR0 <- GR4
  75         LD      GR0,LEN         ; GR0 <- LEN
  76         JUMP    FIN             ; プログラム終端へジャンプ
  77 LENOV   LAD     GR0,#FFFF       ; 文字列が最大長より大きい場合、GR0 <- #FFFF
  78         SRA     GR0,1           ; ↓ オーバーフロー発生
  79 FIN     POP     GR5
  80         POP     GR4
  81         POP     GR3
  82         POP     GR2
  83         POP     GR1
  84         RET
  85 ZERO    DC      '0'
  86 NINE    DC      '9'
  87 MAXLEN  DC      5               ; 文字列の最大長
  88 STR     DS      1
  89 LEN     DS      1
  90 NLEN    DS      1
  91         END
  92 ;;; 0〜65535の範囲にある正数のかけ算（筆算方式）を行う
  93 ;;; 入力 GR1:被乗数 GR2:乗数
  94 ;;; 出力 GR0:積の下位WORD GR3:積の上位WORD
  95 ;;; 積が65535より大きい場合は、オーバーフロー
  96 MULL    START
  97         PUSH    0,GR4
  98         PUSH    0,GR5
  99         XOR     GR0,GR0         ; 積
 100         XOR     GR3,GR3         ; 上位word
 101         XOR     GR5,GR5         ; 上位wordの一時値
 102         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
 103         JZE     CHKOV           ; ↓
 104         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
 105         JZE     CHKOV           ; ↓
 106         LAD     GR4,1           ; 対象ビット
 107 LOOP    PUSH    0,GR4           ; ループ先頭。GR2のビット中でGR4が示すビットが0の場合、NEXTへジャンプ
 108         AND     GR4,GR2         ; ↓
 109         POP     GR4             ; ↓
 110         JZE     NEXT1           ; ↓
 111         ADDL    GR3,GR5         ; GR3 <- GR3 + GR5
 112         ADDL    GR0,GR1         ; GR0 <- GR0 + GR1
 113         JOV     AHB1            ; GR0がオーバーフローした場合、AHB1へジャンプ
 114         JUMP    NEXT1           ; ↓
 115 AHB1    LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 116 NEXT1   SLL     GR4,1           ; GR4を1回左シフト
 117         JOV     CHKOV           ; ↓
 118         SLL     GR5,1           ; GR5を1回左シフト
 119         CPL     GR4,GR2         ; (GR4 > GR2)の場合、CHKOVへジャンプ
 120         JPL     CHKOV           ; ↓
 121         SLL     GR1,1           ; GR1を1回左シフト
 122         JOV     AHB2            ; GR1がオーバーフローした場合、AHBへジャンプ
 123         JUMP    NEXT2           ; ↓
 124 AHB2    LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
 125 NEXT2   JUMP    LOOP            ; ループ終端
 126 CHKOV   AND     GR3,GR3         ; GR3 = 0の場合、終了
 127         JZE     FIN             ; ↓
 128         LAD     GR4,#FFFF       ; GR3 <> 0の場合、オーバーフロー
 129         SLL     GR4,1           ; ↓
 130 FIN     POP     GR5
 131         POP     GR4
 132         RET
 133         END