as/casl2lib/inl.casl

   1 ;;; 入力された数値をGR0に格納する
   2 INL     START
   3         RPUSH
   4         IN      IBUF,ILEN       ; 入力文字列を格納
   5         XOR     GR1,GR1         ; GR1:各桁の数値 初期化
   6         LAD     GR2,10          ; GR2:10進数の「10」 初期化
   7         LAD     GR3,0           ; GR3:値の一時格納 初期化
   8         LAD     GR4,0           ; GR4:インデックス 初期化
   9 STOL    CPL     GR4,ILEN        ; ループ先頭。(GR4 = ILEN)の場合、ループ脱出
  10         JZE     CP              ; ↓
  11         LD      GR1,IBUF,GR4    ; GR1に、入力文字列中の次の桁を格納
  12         CPL     GR1,ZERO        ; (GR1 < '0')の場合、IOVへジャンプ
  13         JMI     OV              ; ↓
  14         CPL     GR1,NINE        ; (GR1 > '9')の場合、IOVへジャンプ
  15         JPL     OV              ; ↓
  16         SUBL    GR1,ZERO        ; GR1の文字を、対応する数値に変換
  17         ST      GR4,NLEN        ; GR4 <- ILEN - NLEN - 1
  18         LD      GR4,ILEN        ; ↓
  19         SUBA    GR4,NLEN        ; ↓
  20 MUL10   CPA     GR4,=1          ; ループ先頭。GR1 <- 10 ** GR4
  21         JZE     NEXT            ; (GR4 = 1)の場合、ループ脱出
  22         JMI     NEXT            ; ↓
  23         CALL    MULL            ; MULLを呼び出し、GR0 <- GR1 * GR2
  24         LD      GR1,GR0         ; GR1 <- GR0
  25         LAD     GR4,-1,GR4      ; GR4 <- GR4 -1
  26         JUMP    MUL10           ; ループ終端
  27 NEXT    LD      GR4,NLEN        ; GR4 <- NLEN。復元
  28         ADDL    GR3,GR1         ; GR3 <- GR3 + GR1
  29         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  30         JUMP    STOL            ; ループ終端
  31 OV      LAD     GR0,1           ; GR0 <- 0。オーバーフローを強制的に発生させる
  32         ADDL    GR0,=#FFFF      ; ↓
  33         JUMP    FIN             ; FINへジャンプ
  34 CP      LD      GR0,GR3         ; GR0 <- GR3
  35 FIN     RPOP
  36         RET
  37 ZERO    DC      '0'
  38 NINE    DC      '9'
  39 IBUF    DS      5
  40 ILEN    DS      1
  41 NLEN    DS      1
  42         END
  43 ;;; 0〜65535の範囲にある正数のかけ算（筆算方式）を行う
  44 ;;; 入力 GR1:被乗数 GR2:乗数
  45 ;;; 出力 GR0:積
  46 ;;; 積が65535より大きい場合は、GR0は積の下位16ビットになり、オーバーフロー
  47 MULL    START
  48         PUSH    0,GR1
  49         PUSH    0,GR3
  50         XOR     GR0,GR0         ; 積
  51         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  52         JZE     FIN             ; ↓
  53         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  54         JZE     FIN             ; ↓
  55         LAD     GR3,1           ; 対象ビット
  56 LOOP    PUSH    0,GR3           ; ループ先頭。GR2のビット中でGR3が示すビットが0の場合、NEXTへジャンプ
  57         AND     GR3,GR2         ; ↓
  58         POP     GR3             ; ↓
  59         JZE     NEXT            ; ↓
  60         ADDL    GR0,GR1         ; GR0 <- GR0 + GR1
  61         JOV     FIN             ; GR0がオーバーフローした場合、ループ脱出
  62 NEXT    SLL     GR3,1           ; GR3を1回左シフト
  63         AND     GR3,GR3         ; (GR3 = 0)の場合、ループ脱出
  64         JZE     FIN             ; ↓
  65         CPL     GR3,GR2         ; (GR3 > GR2)の場合、ループ脱出
  66         JPL     FIN             ; ↓
  67         SLL     GR1,1           ; GR1を1回左シフト
  68         JOV     FIN             ; GR1がオーバーフローした場合、ループ脱出
  69         JUMP    LOOP            ; ループ終端
  70 FIN     POP     GR3
  71         POP     GR1
  72         RET
  73         END