as/casl2lib/inl.casl

   1 ;;; 数値の入力を受け付ける
   2 ;;; 入力 （SVC）
   3 ;;; 出力 GR1: 入力された数値 GR0: 文字の長さ
   4 INL     START
   5         PUSH    0,GR2
   6         PUSH    0,GR3
   7         PUSH    0,GR4
   8         IN      IBUF,ILEN       ; 入力文字列を格納
   9         LD      GR0,ILEN        ; ILEN = 0の場合、FINへジャンプ
  10         JZE     FIN             ; ↓
  11         XOR     GR1,GR1         ; GR1:各桁の数値 初期化
  12         LAD     GR2,10          ; GR2:10進数の「10」 初期化
  13         LAD     GR3,0           ; GR3:値の一時格納 初期化
  14         LAD     GR4,0           ; GR4:インデックス 初期化
  15 STOL    CPL     GR4,ILEN        ; ループ先頭。(GR4 = ILEN)の場合、ループ脱出
  16         JZE     CP              ; ↓
  17         LD      GR1,IBUF,GR4    ; GR1に、入力文字列中の次の桁を格納
  18         CPL     GR1,ZERO        ; (GR1 < '0')の場合、IOVへジャンプ
  19         JMI     OV              ; ↓
  20         CPL     GR1,NINE        ; (GR1 > '9')の場合、IOVへジャンプ
  21         JPL     OV              ; ↓
  22         SUBL    GR1,ZERO        ; GR1の文字を、対応する数値に変換
  23         ST      GR4,NLEN        ; GR4 <- ILEN - NLEN - 1
  24         LD      GR4,ILEN        ; ↓
  25         SUBA    GR4,NLEN        ; ↓
  26 MUL10   CPA     GR4,=1          ; ループ先頭。GR1 <- 10 ** GR4
  27         JZE     NEXT            ; (GR4 = 1)の場合、ループ脱出
  28         JMI     NEXT            ; ↓
  29         CALL    MULL            ; MULLを呼び出し、GR0 <- GR1 * GR2
  30         LD      GR1,GR0         ; GR1 <- GR0
  31         LAD     GR4,-1,GR4      ; GR4 <- GR4 -1
  32         JUMP    MUL10           ; ループ終端
  33 NEXT    LD      GR4,NLEN        ; GR4 <- NLEN。復元
  34         ADDL    GR3,GR1         ; GR3 <- GR3 + GR1
  35         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  36         JUMP    STOL            ; ループ終端
  37 OV      LAD     GR0,#8000       ; GR0 <- 0。オーバーフローを強制的に発生させる
  38         SLL     GR0,1           ; ↓
  39         JUMP    FIN             ; FINへジャンプ
  40 CP      LD      GR1,GR3         ; GR0 <- GR3
  41         LD      GR0,ILEN        ; GR0 <- ILEN
  42 FIN     POP     GR4
  43         POP     GR3
  44         POP     GR2
  45         RET
  46 ZERO    DC      '0'
  47 NINE    DC      '9'
  48 IBUF    DS      5
  49 ILEN    DS      1
  50 NLEN    DS      1
  51         END
  52 ;;; 0〜65535の範囲にある正数のかけ算（筆算方式）を行う
  53 ;;; 入力 GR1:被乗数 GR2:乗数
  54 ;;; 出力 GR0:積
  55 ;;; 積が65535より大きい場合は、GR0は積の下位16ビットになり、オーバーフロー
  56 MULL    START
  57         PUSH    0,GR1
  58         PUSH    0,GR3
  59         XOR     GR0,GR0         ; 積
  60         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  61         JZE     FIN             ; ↓
  62         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  63         JZE     FIN             ; ↓
  64         LAD     GR3,1           ; 対象ビット
  65 LOOP    PUSH    0,GR3           ; ループ先頭。GR2のビット中でGR3が示すビットが0の場合、NEXTへジャンプ
  66         AND     GR3,GR2         ; ↓
  67         POP     GR3             ; ↓
  68         JZE     NEXT            ; ↓
  69         ADDL    GR0,GR1         ; GR0 <- GR0 + GR1
  70         JOV     FIN             ; GR0がオーバーフローした場合、ループ脱出
  71 NEXT    SLL     GR3,1           ; GR3を1回左シフト
  72         AND     GR3,GR3         ; (GR3 = 0)の場合、ループ脱出
  73         JZE     FIN             ; ↓
  74         CPL     GR3,GR2         ; (GR3 > GR2)の場合、ループ脱出
  75         JPL     FIN             ; ↓
  76         SLL     GR1,1           ; GR1を1回左シフト
  77         JOV     FIN             ; GR1がオーバーフローした場合、ループ脱出
  78         JUMP    LOOP            ; ループ終端
  79 FIN     POP     GR3
  80         POP     GR1
  81         RET
  82         END