as/casl2lib/l2str.casl

   1 ;;; 符号なし整数を文字列に変換する。
   2 ;;; 符号なし整数を文字列に変換する。
   3 ;;; 入力 GR1:符号なし整数 G2:変換した文字列を格納するメモリーの先頭アドレス
   4 ;;; 出力 GR0:文字列の長さ （同上）
   5 ;;; 依存プログラム: DIVL, REV
   6 L2STR   START
   7         PUSH    0,GR1
   8         PUSH    0,GR4
   9         XOR     GR0,GR0         ; GR0 <- 0
  10         LD      GR4,GR2         ; GR4 <- GR2
  11         PUSH    0,GR2           ; GR2の保存
  12         LAD     GR2,10          ; GR2 <- 10。10進数の 10
  13 LOOP    LD      GR1,GR1         ; ループ先頭。GR1をテスト
  14         JZE     SRT             ; GR1が0の場合、ループ終了
  15         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
  16         ADDL    GR3,='0'        ; GR3を文字に変換
  17         ST      GR3,0,GR4       ; GR4のアドレスに、GR3を格納
  18         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  19         LD      GR1,GR0         ; GR0の商をGR1にコピー
  20         JUMP    LOOP            ; ループ終端
  21 SRT     POP     GR2             ; GR2の復元
  22         LD      GR1,GR2         ; GR1に文字列のアドレスを格納
  23         SUBL    GR4,GR2         ; GR4 <- GR4 - GR2
  24         LD      GR2,GR4         ; GR2 <- GR4
  25         CALL    REV             ; 文字列を逆順に並べ替え
  26         LD      GR0,GR2         ; GR0 <- GR4 文字列の長さを格納
  27         POP     GR4
  28         POP     GR1
  29         RET
  30         END
  31 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  32 ;;; 入力 GR1:被除数 GR2:除数
  33 ;;; 出力 GR0:商 GR3:剰余
  34 ;;; (GR2 = 0)の場合、GR0 GR3とも0になり、オーバーフロー
  35 DIVL    START
  36         PUSH    0,GR1
  37         PUSH    0,GR2
  38         PUSH    0,GR4
  39         XOR     GR0,GR0         ; GR0:商 初期化
  40         XOR     GR3,GR3         ; GR3:剰余 初期化
  41         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  42         JZE     DIVZERO         ; ↓
  43         AND     GR1,GR1         ; (GR1 = 0)の場合、FINへジャンプ
  44         JZE     FIN             ; ↓
  45         ST      GR2,Y           ; YにGR2の初期値を保存
  46         LAD     GR4,1           ; GR4:対象ビットのインデックス 初期化
  47 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  48         JPL     LOOP            ; ↓
  49         SLL     GR4,1           ; GR4を1回左シフト
  50         ST      GR2,TMP         ; GR2の値をTMPに退避
  51         SLL     GR2,1           ; GR2を1回左シフト
  52         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  53         JUMP    SL              ; ループ終端
  54 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  55         SRL     GR4,1           ; GR4を1回右シフト
  56         JUMP    LPIN            ; LPINへジャンプ
  57 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  58         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  59         SRL     GR2,1           ; GR2を1回右シフト
  60         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  61         JMI     SETMOD          ; ↓
  62         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  63         JMI     LOOP            ; ↓
  64 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  65         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  66         JUMP    LOOP            ; ループ終端
  67 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  68         SLL     GR3,1           ; ↓
  69         JUMP    FIN             ; FIN へジャンプ
  70 SETMOD  LD      GR3,GR1         ; GR3 <- GR1。剰余の設定
  71 FIN     POP     GR4
  72         POP     GR2
  73         POP     GR1
  74         RET
  75 Y       DS      1
  76 TMP     DS      1
  77         END
  78 ;;; メモリー上にある指定されたアドレス、長さの文字列を逆順に並べ替える
  79 ;;;     例: 12345 -> 54321、54321- -> -12345
  80 ;;; 入力 GR1:文字列のアドレス GR2:文字列の長さ
  81 ;;; 出力 （同上）
  82 REV     START
  83         RPUSH
  84         LAD     GR3,0           ; GR3の初期化
  85 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  86         JZE     NEXT            ; ↓
  87         LD      GR4,GR1         ; GR4 <- GR1
  88         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  89         LD      GR5,0,GR4       ; GR5 <- GR4アドレスの値
  90         PUSH    0,GR5           ; GR5をプッシュ
  91         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  92         JUMP    PU              ; ループ終端
  93 NEXT    LAD     GR3,0           ; GR3の初期化
  94 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  95         JZE     FIN             ; ↓
  96         POP     GR5             ; GR5にポップ
  97         LD      GR4,GR1         ; GR4にGR1の値をコピー
  98         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  99         ST      GR5,0,GR4       ; GR4のアドレス <- GR5の値
 100         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 101         JUMP    PO              ; ループ終端
 102 FIN     RPOP
 103         RET
 104         END