as/casl2lib/mula.casl

   1 ;;; -32767〜32767の範囲にある正数のかけ算（筆算方式）を行う
   2 ;;; 入力 GR1:被乗数 GR2:乗数
   3 ;;; 出力 GR0:積
   4 ;;; 被乗数または乗数が-32768の場合は、オーバーフロー
   5 ;;; 積が-32767未満または32767より大きい場合は、GR0は積の下位16ビットになり、オーバーフロー
   6 MULA    START
   7         RPUSH
   8         XOR     GR0,GR0         ; 積
   9         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  10         JZE     FIN             ; ↓
  11         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  12         JZE     FIN             ; ↓
  13         LAD     GR3,1           ; 対象ビット
  14         XOR     GR4,GR4         ; マイナスフラグ
  15 CHK1    AND     GR1,GR1         ; (GR1 > 0)の場合は、CHK2へジャンプ
  16         JPL     CHK2            ; ↓
  17         XOR     GR1,ALLON       ; GR1の正負を反転
  18         ADDA    GR1,ONE         ; ↓
  19         JOV     FIN             ; (GR1 = -32768)の場合は終了
  20         XOR     GR4,ONE         ; GR4 <- 1
  21 CHK2    AND     GR2,GR2         ; (GR1 > 0)の場合は、LOOPへジャンプ
  22         JPL     MUL             ; ↓
  23         XOR     GR2,ALLON       ; GR2の正負を反転
  24         ADDA    GR2,ONE         ; ↓
  25         JOV     FIN             ; (GR2 = -32768)の場合は終了
  26         XOR     GR4,ONE         ; マイナスフラグを反転
  27 MUL     CALL    MULL            ; GR0 <- GR1 * GR2
  28         JOV     FIN
  29         AND     GR0,GR0
  30         JMI     OV
  31 MIN     AND     GR4,GR4         ; マイナスフラグがオフの場合、終了
  32         JZE     FIN             ; ↓
  33         XOR     GR0,ALLON       ; GR1の正負を反転
  34         ADDA    GR0,ONE         ; ↓
  35         JUMP    FIN
  36 OV      ADDL    GR0,=#8000
  37 FIN     RPOP
  38         RET
  39 ONE     DC      1
  40 ALLON   DC      #FFFF
  41         END
  42 ;;; 0〜65535の範囲にある正数のかけ算（筆算方式）を行う
  43 ;;; 入力 GR1:被乗数 GR2:乗数
  44 ;;; 出力 GR0:積の下位WORD GR3:積の上位WORD
  45 ;;; 積が65535より大きい場合は、オーバーフロー
  46 MULL    START
  47         PUSH    0,GR4
  48         PUSH    0,GR5
  49         XOR     GR0,GR0         ; 積
  50         XOR     GR3,GR3         ; 上位word
  51         XOR     GR5,GR5         ; 上位wordの一時値
  52         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  53         JZE     CHKOV           ; ↓
  54         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  55         JZE     CHKOV           ; ↓
  56         LAD     GR4,1           ; 対象ビット
  57 LOOP    PUSH    0,GR4           ; ループ先頭。GR2のビット中でGR4が示すビットが0の場合、NEXTへジャンプ
  58         AND     GR4,GR2         ; ↓
  59         POP     GR4             ; ↓
  60         JZE     NEXT1           ; ↓
  61         ADDL    GR3,GR5         ; GR3 <- GR3 + GR5
  62         ADDL    GR0,GR1         ; GR0 <- GR0 + GR1
  63         JOV     AHB1            ; GR0がオーバーフローした場合、AHB1へジャンプ
  64         JUMP    NEXT1           ; ↓
  65 AHB1    LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  66 NEXT1   SLL     GR4,1           ; GR4を1回左シフト
  67         JOV     CHKOV           ; ↓
  68         SLL     GR5,1           ; GR5を1回左シフト
  69         CPL     GR4,GR2         ; (GR4 > GR2)の場合、CHKOVへジャンプ
  70         JPL     CHKOV           ; ↓
  71         SLL     GR1,1           ; GR1を1回左シフト
  72         JOV     AHB2            ; GR1がオーバーフローした場合、AHBへジャンプ
  73         JUMP    NEXT2           ; ↓
  74 AHB2    LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  75 NEXT2   JUMP    LOOP            ; ループ終端
  76 CHKOV   AND     GR3,GR3         ; GR3 = 0の場合、終了
  77         JZE     FIN             ; ↓
  78         LAD     GR4,#FFFF       ; GR3 <> 0の場合、オーバーフロー
  79         SLL     GR4,1           ; ↓
  80 FIN     POP     GR5
  81         POP     GR4
  82         RET
  83         END