as/casl2lib/outa.casl

   1 ;;; GR1に格納された値を、10進数の整数値（-32768〜32767）として表示
   2 OUTA    START
   3         RPUSH
   4         LAD     GR2,10          ; GR2に10進数の「10」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         LAD     GR4,0           ; 負数フラグ。GR1が負数の場合、GR4は1
   7         LAD     GR5,0           ; 整数値の長さ
   8         AND     GR1,GR1         ; GR1をテスト
   9         JZE     ZPRT            ; GR1が0の場合、ZPRTにジャンプ
  10         JPL     STI             ; GR1が正数の場合、STIにジャンプ
  11         LAD     GR4,1           ; GR1が負数の場合、GR4をオン
  12         CALL    ABS             ;                  GR1を正数に変換
  13 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  14         JMI     STLST           ; ↓
  15         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
  16         LD      GR1,GR3         ; GR1にGR3をコピー
  17         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  18         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  19         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  20         LD      GR1,GR0         ; GR0をGR1にコピー
  21         JUMP    STI             ; ループ終端
  22 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  23         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  24         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  25         AND     GR4,GR4         ; 正数の場合
  26         JZE     PRT             ; ↓
  27         LD      GR1,='-'        ; 負数の場合、「-」をSTR領域に格納
  28         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  29         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  30         JUMP    PRT             ; PRTにジャンプ
  31 ZPRT    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  32         ST      GR1,STR,GR5     ; (STR + GR5) <- GR1
  33         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  34 PRT     ST      GR5,LEN         ; LEN <- GR5
  35         LD      GR2,LEN         ; GR2にLENの値を格納
  36         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  37         CALL    REV             ; 文字列を逆順に並べ替え
  38         OUT     STR,LEN         ; 文字列を出力
  39         RPOP
  40         RET
  41 STR     DS      17
  42 LEN     DS      1
  43 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  44         END
  45 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  46 ;;; 入力 GR1:被除数 GR2:除数
  47 ;;; 出力 GR0:商 GR3:剰余
  48 ;;; (GR2 = 0)の場合、GR0 GR3とも0になり、オーバーフロー
  49 DIVL    START
  50         PUSH    0,GR1
  51         PUSH    0,GR2
  52         PUSH    0,GR4
  53         XOR     GR0,GR0         ; GR0:商 初期化
  54         XOR     GR3,GR3         ; GR3:剰余 初期化
  55         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  56         JZE     DIVZERO         ; ↓
  57         AND     GR1,GR1         ; (GR1 = 0)の場合、FINへジャンプ
  58         JZE     FIN             ; ↓
  59         ST      GR2,Y           ; YにGR2の初期値を保存
  60         LAD     GR4,1           ; GR4:対象ビットのインデックス 初期化
  61 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  62         JPL     LOOP            ; ↓
  63         SLL     GR4,1           ; GR4を1回左シフト
  64         ST      GR2,TMP         ; GR2の値をTMPに退避
  65         SLL     GR2,1           ; GR2を1回左シフト
  66         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  67         JUMP    SL              ; ループ終端
  68 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  69         SRL     GR4,1           ; GR4を1回右シフト
  70         JUMP    LPIN            ; LPINへジャンプ
  71 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  72         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  73         SRL     GR2,1           ; GR2を1回右シフト
  74         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  75         JMI     SETMOD          ; ↓
  76         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  77         JMI     LOOP            ; ↓
  78 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  79         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  80         JUMP    LOOP            ; ループ終端
  81 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  82         SLL     GR3,1           ; ↓
  83         JUMP    FIN             ; FIN へジャンプ
  84 SETMOD  LD      GR3,GR1         ; GR3 <- GR1。剰余の設定
  85 FIN     POP     GR4
  86         POP     GR2
  87         POP     GR1
  88         RET
  89 Y       DS      1
  90 TMP     DS      1
  91         END
  92 ;;; メモリー上にある指定されたアドレス、長さの文字列を逆順に並べ替える
  93 ;;;     例: 12345 -> 54321、54321- -> -12345
  94 ;;; 入力 GR1:文字列のアドレス GR2:文字列の長さ
  95 ;;; 出力 （同上）
  96 REV     START
  97         RPUSH
  98         LAD     GR3,0           ; GR3の初期化
  99 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 100         JZE     NEXT            ; ↓
 101         LD      GR4,GR1         ; GR4 <- GR1
 102         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 103         LD      GR5,0,GR4       ; GR5 <- GR4アドレスの値
 104         PUSH    0,GR5           ; GR5をプッシュ
 105         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 106         JUMP    PU              ; ループ終端
 107 NEXT    LAD     GR3,0           ; GR3の初期化
 108 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 109         JZE     FIN             ; ↓
 110         POP     GR5             ; GR5にポップ
 111         LD      GR4,GR1         ; GR4にGR1の値をコピー
 112         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 113         ST      GR5,0,GR4       ; GR4のアドレス <- GR5の値
 114         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 115         JUMP    PO              ; ループ終端
 116 FIN     RPOP
 117         RET
 118         END
 119 ;;; GR1を絶対値に変換する
 120 ;;; 入力 GR1:-32768〜32767の整数
 121 ;;; 出力 GR1:入力された整数の絶対値
 122 ;;;       OF:入力されたGR1が-32768の場合、1
 123 ;;;       SF:入力されたGR1が負数(-32767〜-1)の場合、1
 124 ABS     START
 125         AND     GR1,GR1
 126         JPL     FIN
 127         JZE     FIN
 128         XOR     GR1,ALLON
 129         ADDA    GR1,ONE
 130         JOV     FIN
 131         CPL     GR1,ALLON
 132 FIN     RET
 133 ONE     DC      1
 134 ALLON   DC      #FFFF
 135         END