as/casl2lib/outb.casl

   1 ;;; GR1に格納された値を、2進数値として表示
   2 OUTB    START
   3         RPUSH
   4         LD      GR2,BIN         ; GR2に2進数の「2」を格納。
   5         XOR     GR4,GR4         ; GR4: 2進数値の長さ
   6 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
   7         JMI     STLST           ; ↓
   8         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
   9         LD      GR1,GR3         ; GR1にGR3をコピー
  10         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  11         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  12         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  13         LD      GR1,GR0         ; GR0をGR1にコピー
  14         JUMP    STI             ; ループ終端
  15 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  16         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  17         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  18 EMLOOP  CPL     GR4,DIG         ; ループ先頭。(GR4 = DIG)の場合は、ループ脱出
  19         JZE     PRT             ; ↓
  20         LD      GR1,NCHAR       ; GR1 <- NCHAR:'0'
  21         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  22         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  23         JUMP    EMLOOP          ; ループ終端
  24 PRT     ST      GR4,LEN         ; LEN <- GR4
  25         LD      GR2,LEN         ; GR2にLENの値を格納
  26         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  27         CALL    REV             ; 文字列を逆順に並べ替え
  28         OUT     STR,LEN         ; 文字列を出力
  29         RPOP
  30         RET
  31 STR     DS      17
  32 LEN     DS      1
  33 BIN     DC      2
  34 NCHAR   DC      '01'
  35 SPC     DC      ' '
  36 DIG     DC      16
  37         END
  38 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  39 ;;; 入力 GR1:被除数 GR2:除数
  40 ;;; 出力 GR0:商 GR3:剰余
  41 ;;; (GR2 = 0)の場合、GR0 GR3とも0になり、オーバーフロー
  42 DIVL    START
  43         PUSH    0,GR1
  44         PUSH    0,GR2
  45         PUSH    0,GR4
  46         XOR     GR0,GR0         ; GR0:商 初期化
  47         XOR     GR3,GR3         ; GR3:剰余 初期化
  48         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  49         JZE     DIVZERO         ; ↓
  50         AND     GR1,GR1         ; (GR1 = 0)の場合、FINへジャンプ
  51         JZE     FIN             ; ↓
  52         ST      GR2,Y           ; YにGR2の初期値を保存
  53         LAD     GR4,1           ; GR4:対象ビットのインデックス 初期化
  54 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  55         JPL     LOOP            ; ↓
  56         SLL     GR4,1           ; GR4を1回左シフト
  57         ST      GR2,TMP         ; GR2の値をTMPに退避
  58         SLL     GR2,1           ; GR2を1回左シフト
  59         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  60         JUMP    SL              ; ループ終端
  61 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  62         SRL     GR4,1           ; GR4を1回右シフト
  63         JUMP    LPIN            ; LPINへジャンプ
  64 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  65         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  66         SRL     GR2,1           ; GR2を1回右シフト
  67         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  68         JMI     SETMOD          ; ↓
  69         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  70         JMI     LOOP            ; ↓
  71 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  72         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  73         JUMP    LOOP            ; ループ終端
  74 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  75         SLL     GR3,1           ; ↓
  76         JUMP    FIN             ; FIN へジャンプ
  77 SETMOD  LD      GR3,GR1         ; GR3 <- GR1。剰余の設定
  78 FIN     POP     GR4
  79         POP     GR2
  80         POP     GR1
  81         RET
  82 Y       DS      1
  83 TMP     DS      1
  84         END
  85 ;;; メモリー上にある指定されたアドレス、長さの文字列を逆順に並べ替える
  86 ;;;     例: 12345 -> 54321、54321- -> -12345
  87 ;;; 入力 GR1:文字列のアドレス GR2:文字列の長さ
  88 ;;; 出力 （同上）
  89 REV     START
  90         RPUSH
  91         LAD     GR3,0           ; GR3の初期化
  92 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  93         JZE     NEXT            ; ↓
  94         LD      GR4,GR1         ; GR4 <- GR1
  95         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  96         LD      GR5,0,GR4       ; GR5 <- GR4アドレスの値
  97         PUSH    0,GR5           ; GR5をプッシュ
  98         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  99         JUMP    PU              ; ループ終端
 100 NEXT    LAD     GR3,0           ; GR3の初期化
 101 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 102         JZE     FIN             ; ↓
 103         POP     GR5             ; GR5にポップ
 104         LD      GR4,GR1         ; GR4にGR1の値をコピー
 105         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 106         ST      GR5,0,GR4       ; GR4のアドレス <- GR5の値
 107         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 108         JUMP    PO              ; ループ終端
 109 FIN     RPOP
 110         RET
 111         END