as/casl2lib/outb.casl

   1 ;;; GR1に格納された値を、2進数値として表示
   2 OUTB    START
   3         RPUSH
   4         LAD     GR2,2           ; GR2に2進数の「2」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         XOR     GR4,GR4         ; 2進数値の長さ
   7         AND     GR1,GR1         ; GR1をテスト
   8         JZE     ZERO            ; GR1が0の場合、ZEROにジャンプ
   9 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  10         JMI     STLST           ; ↓
  11         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
  12         LD      GR1,GR3         ; GR1にGR3をコピー
  13         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  14         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  15         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  16         LD      GR1,GR0         ; GR0をGR1にコピー
  17         JUMP    STI             ; ループ終端
  18 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  19         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  20         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  21         JUMP    EMB             ; EMBにジャンプ
  22 ZERO    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  23         ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
  24         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  25 EMB     LD      GR1,NCHAR       ; GR1 <- '0'
  26 EMLOOP  CPA     GR4,DIG         ; ループ先頭。(GR4 = DIG)の場合は、ループ脱出
  27         JZE     PRT             ; ↓
  28         ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
  29         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  30         JUMP    EMLOOP          ; ループ終端
  31 PRT     ST      GR4,LEN         ; LEN <- GR4
  32         LD      GR2,LEN         ; GR2にLENの値を格納
  33         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  34         CALL    REV             ; 文字列を逆順に並べ替え
  35         OUT     STR,LEN         ; 文字列を出力
  36         RPOP
  37         RET
  38 STR     DS      17
  39 LEN     DS      1
  40 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  41 DIG     DC      16
  42         END
  43 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  44 ;;; 入力 GR1:被除数 GR2:除数
  45 ;;; 出力 GR0:商 GR3:剰余
  46 ;;; GR2が0の場合は、GR0、GR3とも0になり、オーバーフロー
  47 DIVL    START
  48         PUSH    0,GR1
  49         PUSH    0,GR2
  50         PUSH    0,GR4
  51         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  52         JZE     DIVZERO         ; ↓
  53         ST      GR2,Y           ; YにGR2の初期値を保存
  54         LAD     GR0,0           ; GR0の初期化
  55         LAD     GR3,0           ; GR3の初期化
  56         LAD     GR4,1           ; GR4の初期化。対象ビットを表す
  57 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  58         JPL     LOOP            ; ↓
  59         SLL     GR4,1           ; GR4を1回左シフト
  60         ST      GR2,TMP         ; GR2の値をTMPに退避
  61         SLL     GR2,1           ; GR2を1回左シフト
  62         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  63         JUMP    SL              ; ループ終端
  64 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  65         SRL     GR4,1           ; GR4を1回右シフト
  66         JUMP    LPIN            ; LPINへジャンプ
  67 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  68         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  69         SRL     GR2,1           ; GR2を1回右シフト
  70         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  71         JMI     SETMOD          ; ↓
  72         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  73         JMI     LOOP            ; ↓
  74 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  75         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  76         JUMP    LOOP            ; ループ終端
  77 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  78         SLL     GR3,1           ; ↓
  79         JUMP    FIN             ; FIN へジャンプ
  80 SETMOD  LD      GR3,GR1
  81 FIN     POP     GR4
  82         POP     GR2
  83         POP     GR1
  84         RET
  85 Y       DS      1
  86 TMP     DS      1
  87         END
  88 ;; アドレスがGR1、長さがGR2の文字列を逆順に並べ替える
  89 ;; 例: 12345 -> 54321、54321- -> -12345
  90 REV     START
  91         RPUSH
  92         LAD     GR3,0           ; GR3の初期化
  93 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  94         JZE     NEXT            ; ↓
  95         LD      GR4,GR1         ; GR4にGR1の値をコピー
  96         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
  97         LD      GR5,0,GR4       ; GR5にアドレスGR4の値を格納
  98         PUSH    0,GR5           ; GR5をプッシュ
  99         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 100         JUMP    PU              ; ループ終端
 101 NEXT    LAD     GR3,0           ; GR3の初期化
 102 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 103         JZE     FIN             ; ↓
 104         POP     GR5             ; GR5にポップ
 105         LD      GR4,GR1         ; GR4にGR1の値をコピー
 106         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 107         ST      GR5,0,GR4       ; アドレスGR4にGR5の値を格納
 108         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 109         JUMP    PO              ; ループ終端
 110 FIN     RPOP
 111         RET
 112         END