as/casl2lib/outb.casl

   1 ;;; GR1に格納された値を、2進数値として表示
   2 OUTB    START
   3         RPUSH
   4         LAD     GR2,2           ; GR2に2進数の「2」を格納。
   5         LAD     GR0,0           ; GR0 <- 0
   6         XOR     GR4,GR4         ; 2進数値の長さ
   7         AND     GR1,GR1         ; GR1をテスト
   8         JZE     ZERO            ; GR1が0の場合、ZEROにジャンプ
   9 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
  10         JMI     STLST           ; ↓
  11         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
  12         LD      GR1,GR3         ; GR1にGR3をコピー
  13         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  14         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  15         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  16         LD      GR1,GR0         ; GR0をGR1にコピー
  17         JUMP    STI             ; ループ終端
  18 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  19         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  20         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  21         JUMP    EMB             ; EMBにジャンプ
  22 ZERO    LD      GR1,NCHAR       ; 「0」をSTR領域に格納
  23         ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
  24         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  25 EMB     LD      GR1,NCHAR       ; GR1 <- '0'
  26 EMLOOP  CPA     GR4,DIG         ; ループ先頭。(GR4 = DIG)の場合は、ループ脱出
  27         JZE     PRT             ; ↓
  28         ST      GR1,STR,GR4     ; ↓ (STR + GR4) <- GR1
  29         LAD     GR4,1,GR4       ; ↓ GR4 <- GR4 + 1
  30         JUMP    EMLOOP          ; ループ終端
  31 PRT     ST      GR4,LEN         ; LEN <- GR4
  32         LD      GR2,LEN         ; GR2にLENの値を格納
  33         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  34         CALL    REV             ; 文字列を逆順に並べ替え
  35         OUT     STR,LEN         ; 文字列を出力
  36         RPOP
  37         RET
  38 STR     DS      17
  39 LEN     DS      1
  40 NCHAR   DC      '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
  41 DIG     DC      16
  42         END
  43 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  44 ;;; 入力 GR1:被除数 GR2:除数
  45 ;;; 出力 GR0:商 GR3:剰余
  46 ;;; (GR2 = 0)の場合、GR0 GR3とも0になり、オーバーフロー
  47 DIVL    START
  48         PUSH    0,GR1
  49         PUSH    0,GR2
  50         PUSH    0,GR4
  51         XOR     GR0,GR0         ; GR0:商 初期化
  52         XOR     GR3,GR3         ; GR3:剰余 初期化
  53         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  54         JZE     DIVZERO         ; ↓
  55         AND     GR1,GR1         ; (GR1 = 0)の場合、FINへジャンプ
  56         JZE     FIN             ; ↓
  57         ST      GR2,Y           ; YにGR2の初期値を保存
  58         LAD     GR4,1           ; GR4:対象ビットのインデックス 初期化
  59 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  60         JPL     LOOP            ; ↓
  61         SLL     GR4,1           ; GR4を1回左シフト
  62         ST      GR2,TMP         ; GR2の値をTMPに退避
  63         SLL     GR2,1           ; GR2を1回左シフト
  64         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  65         JUMP    SL              ; ループ終端
  66 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  67         SRL     GR4,1           ; GR4を1回右シフト
  68         JUMP    LPIN            ; LPINへジャンプ
  69 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  70         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  71         SRL     GR2,1           ; GR2を1回右シフト
  72         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  73         JMI     SETMOD          ; ↓
  74         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  75         JMI     LOOP            ; ↓
  76 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  77         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  78         JUMP    LOOP            ; ループ終端
  79 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  80         SLL     GR3,1           ; ↓
  81         JUMP    FIN             ; FIN へジャンプ
  82 SETMOD  LD      GR3,GR1         ; GR3 <- GR1。剰余の設定
  83 FIN     POP     GR4
  84         POP     GR2
  85         POP     GR1
  86         RET
  87 Y       DS      1
  88 TMP     DS      1
  89         END
  90 ;;; メモリー上にある指定されたアドレス、長さの文字列を逆順に並べ替える
  91 ;;;     例: 12345 -> 54321、54321- -> -12345
  92 ;;; 入力 GR1:文字列のアドレス GR2:文字列の長さ
  93 ;;; 出力 （同上）
  94 REV     START
  95         RPUSH
  96         LAD     GR3,0           ; GR3の初期化
  97 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  98         JZE     NEXT            ; ↓
  99         LD      GR4,GR1         ; GR4 <- GR1
 100         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 101         LD      GR5,0,GR4       ; GR5 <- GR4アドレスの値
 102         PUSH    0,GR5           ; GR5をプッシュ
 103         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 104         JUMP    PU              ; ループ終端
 105 NEXT    LAD     GR3,0           ; GR3の初期化
 106 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 107         JZE     FIN             ; ↓
 108         POP     GR5             ; GR5にポップ
 109         LD      GR4,GR1         ; GR4にGR1の値をコピー
 110         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 111         ST      GR5,0,GR4       ; GR4のアドレス <- GR5の値
 112         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 113         JUMP    PO              ; ループ終端
 114 FIN     RPOP
 115         RET
 116         END