as/casl2lib/outb_w.casl

   1 ;;; GR1に格納された値を、空白付きの2進数値として表示
   2 OUTB    START
   3         RPUSH
   4         LD      GR2,BIN         ; GR2に2進数の「2」を格納。
   5         XOR     GR4,GR4         ; GR4: 2進数値の長さ
   6 STI     CPL     GR1,GR2         ; ループ先頭。(GR1 < GR2)の場合は、ループ脱出
   7         JMI     STLST           ; ↓
   8         CALL    DIVL            ; GR1とGR2の、商をGR0、剰余をGR3に格納
   9         LD      GR1,GR3         ; GR1にGR3をコピー
  10         LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  11         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  12         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  13         LD      GR1,SPC         ; GR1 <- SPC
  14         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  15         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  16         LD      GR1,GR0         ; GR0をGR1にコピー
  17         JUMP    STI             ; ループ終端
  18 STLST   LD      GR1,NCHAR,GR1   ; GR1を文字に変換
  19         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  20         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  21 EMLOOP  CPL     GR4,DIG         ; ループ先頭。(GR4 = DIG)の場合は、ループ脱出
  22         JZE     PRT             ; ↓
  23         LD      GR1,SPC         ; GR1 <- SPC
  24         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  25         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  26         LD      GR1,NCHAR       ; GR1 <- NCHAR:'0'
  27         ST      GR1,STR,GR4     ; (STR + GR4) <- GR1
  28         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  29         JUMP    EMLOOP          ; ループ終端
  30 PRT     ST      GR4,LEN         ; LEN <- GR4
  31         LD      GR2,LEN         ; GR2にLENの値を格納
  32         LAD     GR1,STR         ; GR1に文字列のアドレスを格納
  33         CALL    REV             ; 文字列を逆順に並べ替え
  34         OUT     STR,LEN         ; 文字列を出力
  35         RPOP
  36         RET
  37 STR     DS      32
  38 LEN     DS      1
  39 BIN     DC      2
  40 NCHAR   DC      '01'
  41 SPC     DC      ' '
  42 DIG     DC      31
  43         END
  44 ;;; 0〜65535の範囲にある正数の割算（筆算方式）を行う
  45 ;;; 入力 GR1:被除数 GR2:除数
  46 ;;; 出力 GR0:商 GR3:剰余
  47 ;;; (GR2 = 0)の場合、GR0 GR3とも0になり、オーバーフロー
  48 DIVL    START
  49         PUSH    0,GR1
  50         PUSH    0,GR2
  51         PUSH    0,GR4
  52         XOR     GR0,GR0         ; GR0:商 初期化
  53         XOR     GR3,GR3         ; GR3:剰余 初期化
  54         AND     GR2,GR2         ; (GR2 = 0)の場合、DIVZEROへジャンプ
  55         JZE     DIVZERO         ; ↓
  56         AND     GR1,GR1         ; (GR1 = 0)の場合、FINへジャンプ
  57         JZE     FIN             ; ↓
  58         ST      GR2,Y           ; YにGR2の初期値を保存
  59         LAD     GR4,1           ; GR4:対象ビットのインデックス 初期化
  60 SL      CPL     GR2,GR1         ; ループ先頭。(GR2 > GR1)の場合、LOOPへループ脱出
  61         JPL     LOOP            ; ↓
  62         SLL     GR4,1           ; GR4を1回左シフト
  63         ST      GR2,TMP         ; GR2の値をTMPに退避
  64         SLL     GR2,1           ; GR2を1回左シフト
  65         JOV     YOV             ; オーバーフローの場合は、YOVへジャンプ
  66         JUMP    SL              ; ループ終端
  67 YOV     LD      GR2,TMP         ; GR2の値をTMPから復元
  68         SRL     GR4,1           ; GR4を1回右シフト
  69         JUMP    LPIN            ; LPINへジャンプ
  70 LOOP    SRL     GR4,1           ; ループ先頭。GR4を1回右シフト
  71         JZE     SETMOD          ; (GR4 = 0)の場合、SETMODへループ脱出
  72         SRL     GR2,1           ; GR2を1回右シフト
  73         CPL     GR1,Y           ; (GR1 < Y)の場合、SETMODへループ脱出
  74         JMI     SETMOD          ; ↓
  75         CPL     GR1,GR2         ; (GR1 < GR2)の場合、ループ先頭へジャンプ
  76         JMI     LOOP            ; ↓
  77 LPIN    SUBL    GR1,GR2         ; GR1 <- GR1 - GR2
  78         ADDL    GR0,GR4         ; GR0 <- GR0 + GR4
  79         JUMP    LOOP            ; ループ終端
  80 DIVZERO LAD     GR3,#8000       ; 強制的にオーバーフローを発生させ、GR3 <- 0
  81         SLL     GR3,1           ; ↓
  82         JUMP    FIN             ; FIN へジャンプ
  83 SETMOD  LD      GR3,GR1         ; GR3 <- GR1。剰余の設定
  84 FIN     POP     GR4
  85         POP     GR2
  86         POP     GR1
  87         RET
  88 Y       DS      1
  89 TMP     DS      1
  90         END
  91 ;;; メモリー上にある指定されたアドレス、長さの文字列を逆順に並べ替える
  92 ;;;     例: 12345 -> 54321、54321- -> -12345
  93 ;;; 入力 GR1:文字列のアドレス GR2:文字列の長さ
  94 ;;; 出力 （同上）
  95 REV     START
  96         RPUSH
  97         LAD     GR3,0           ; GR3の初期化
  98 PU      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
  99         JZE     NEXT            ; ↓
 100         LD      GR4,GR1         ; GR4 <- GR1
 101         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 102         LD      GR5,0,GR4       ; GR5 <- GR4アドレスの値
 103         PUSH    0,GR5           ; GR5をプッシュ
 104         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 105         JUMP    PU              ; ループ終端
 106 NEXT    LAD     GR3,0           ; GR3の初期化
 107 PO      CPL     GR3,GR2         ; ループ先頭。(GR3 = GR2)の場合、ループ脱出
 108         JZE     FIN             ; ↓
 109         POP     GR5             ; GR5にポップ
 110         LD      GR4,GR1         ; GR4にGR1の値をコピー
 111         ADDL    GR4,GR3         ; GR4 <- GR4 + GR3
 112         ST      GR5,0,GR4       ; GR4のアドレス <- GR5の値
 113         LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
 114         JUMP    PO              ; ループ終端
 115 FIN     RPOP
 116         RET
 117         END