as/casl2lib/str2l.casl

   1 ;;; *** This file is auto generated. ***
   2 ;;; 0〜65535の範囲にある整数の入力を受け付ける
   3 ;;; 10進数の整数を表す文字列を数値に変換
   4 ;;; 入力 GR1: 文字列を格納するアドレス
   5 ;;;      GR2: 文字列の長さ。1-5を想定
   6 ;;; 出力 GR0: 数値（0〜65535）
   7 ;;;           文字列が長過ぎる場合や数値以外の場合は、GR2に#FFFFを格納
   8 STR2L   START
   9         PUSH    0,GR3
  10         PUSH    0,GR4
  11         XOR     GR0,GR0         ; GR0:初期化
  12         AND     GR2,GR2         ; (GR2 = 0)の場合、FINへジャンプ
  13         JZE     FIN             ; ↓
  14         CPL     GR2,MAXLEN      ; (GR2 > MAXLEN)の場合、LENOVへジャンプ
  15         JPL     LENOV           ; ↓
  16         ST      GR1,STR         ; STR <- GR1 文字列の開始アドレス
  17         ST      GR2,LEN         ; LEN <- GR2
  18         LAD     GR2,10          ; GR2:10進数の「10」
  19         XOR     GR3,GR3         ; GR3:値の一時格納
  20         XOR     GR4,GR4         ; GR4:インデックス
  21 STOL    CPL     GR4,LEN         ; ループ先頭。(GR4 = LEN)の場合、ループ脱出
  22         JZE     CP              ; ↓
  23         LD      GR1,STR         ; GR1に、入力文字列中の次の桁を格納
  24         ADDL    GR1,GR4         ; ↓
  25         LD      GR1,0,GR1       ; ↓
  26         CPL     GR1,ZERO        ; (GR1 < '0')の場合、NANへジャンプ
  27         JMI     NAN             ; ↓
  28         CPL     GR1,NINE        ; (GR1 > '9')の場合、NANへジャンプ
  29         JPL     NAN             ; ↓
  30         SUBL    GR1,ZERO        ; GR1の文字を、対応する数値に変換
  31         ST      GR4,NLEN        ; GR4 <- LEN - NLEN - 1
  32         LD      GR4,LEN         ; ↓
  33         SUBA    GR4,NLEN        ; ↓
  34 MUL10   CPA     GR4,=1          ; ループ先頭。GR1 <- 10 ** GR4
  35         JZE     NEXT            ; (GR4 = 1)の場合、ループ脱出
  36         JMI     NEXT            ; ↓
  37         CALL    MULL            ; MULLを呼び出し、GR0 <- GR1 * GR2
  38         JOV     FIN             ; ↓
  39         LD      GR1,GR0         ; GR1 <- GR0
  40         LAD     GR4,-1,GR4      ; GR4 <- GR4 -1
  41         JUMP    MUL10           ; ループ終端
  42 NEXT    LD      GR4,NLEN        ; GR4 <- NLEN。復元
  43         ADDL    GR3,GR1         ; GR3 <- GR3 + GR1
  44         JOV     FIN             ; ↓
  45         LAD     GR4,1,GR4       ; GR4 <- GR4 + 1
  46         JUMP    STOL            ; ループ終端
  47 NAN     LAD     GR2,#FFFF       ; GR2 <- #FFFF
  48         JUMP    FIN             ; FINへジャンプ
  49 CP      LD      GR1,GR3         ; GR0 <- GR3
  50         LD      GR0,LEN         ; GR0 <- LEN
  51         JUMP    FIN
  52 LENOV   LAD     GR0,#FFFF
  53         SRA     GR0,1
  54 FIN     POP     GR4
  55         POP     GR3
  56         RET
  57 ZERO    DC      '0'
  58 NINE    DC      '9'
  59 MAXLEN  DC      10              ; 10桁の数値まで入力可能
  60 STR     DS      1
  61 LEN     DS      1
  62 NLEN    DS      1
  63         END
  64 ;;; 0〜65535の範囲にある正数のかけ算（筆算方式）を行う
  65 ;;; 入力 GR1:被乗数 GR2:乗数
  66 ;;; 出力 GR0:積
  67 ;;; 積が65535より大きい場合は、GR0は積の下位16ビットになり、オーバーフロー
  68 MULL    START
  69         PUSH    0,GR1
  70         PUSH    0,GR3
  71         XOR     GR0,GR0         ; 積
  72         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  73         JZE     FIN             ; ↓
  74         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  75         JZE     FIN             ; ↓
  76         LAD     GR3,1           ; 対象ビット
  77 LOOP    PUSH    0,GR3           ; ループ先頭。GR2のビット中でGR3が示すビットが0の場合、NEXTへジャンプ
  78         AND     GR3,GR2         ; ↓
  79         POP     GR3             ; ↓
  80         JZE     NEXT            ; ↓
  81         ADDL    GR0,GR1         ; GR0 <- GR0 + GR1
  82         JOV     FIN             ; GR0がオーバーフローした場合、ループ脱出
  83 NEXT    SLL     GR3,1           ; GR3を1回左シフト
  84         AND     GR3,GR3         ; (GR3 = 0)の場合、ループ脱出
  85         JZE     FIN             ; ↓
  86         CPL     GR3,GR2         ; (GR3 > GR2)の場合、ループ脱出
  87         JPL     FIN             ; ↓
  88         SLL     GR1,1           ; GR1を1回左シフト
  89         JOV     FIN             ; GR1がオーバーフローした場合、ループ脱出
  90         JUMP    LOOP            ; ループ終端
  91 FIN     POP     GR3
  92         POP     GR1
  93         RET
  94         END