as/casl2lib/str2l.casl

   1 ;;; 10進数の整数を表す文字列を数値に変換
   2 ;;; 数値の範囲は、0から65535
   3 ;;; 入力 GR1: 文字列を格納するアドレス
   4 ;;;      GR2: 文字列の長さ。最大5けた
   5 ;;; 出力 GR0: 数値
   6 ;;;           文字列が最大長より大きい場合や数値以外の場合は、GR0は#FFFF、OFは1
   7 ;;; 依存プログラム: MULL
   8 STR2L   START
   9         PUSH    0,GR4
  10         PUSH    0,GR5
  11         XOR     GR0,GR0         ; GR0:初期化
  12         AND     GR2,GR2         ; (GR2 = 0)の場合、FINへジャンプ
  13         JZE     FIN             ; ↓
  14         CPL     GR2,MAXLEN      ; (GR2 > MAXLEN)の場合、LENOVへジャンプ
  15         JPL     LENOV           ; ↓
  16         ST      GR1,STR         ; STR <- GR1 文字列の開始アドレス
  17         ST      GR2,LEN         ; LEN <- GR2
  18         LAD     GR2,10          ; GR2:10進数の「10」
  19         XOR     GR4,GR4         ; GR4:値の一時格納
  20         XOR     GR5,GR5         ; GR5:インデックス
  21 STOL    CPL     GR5,LEN         ; ループ先頭。(GR5 = LEN)の場合、ループ脱出
  22         JZE     CP              ; ↓
  23         LD      GR1,STR         ; GR1に、入力文字列中の次の桁を格納
  24         ADDL    GR1,GR5         ; ↓
  25         LD      GR1,0,GR1       ; ↓
  26         CPL     GR1,ZERO        ; (GR1 < '0')の場合、NANへジャンプ
  27         JMI     NAN             ; ↓
  28         CPL     GR1,NINE        ; (GR1 > '9')の場合、NANへジャンプ
  29         JPL     NAN             ; ↓
  30         SUBL    GR1,ZERO        ; GR1の文字を、対応する数値に変換
  31         ST      GR5,NLEN        ; GR5 <- LEN - NLEN - 1
  32         LD      GR5,LEN         ; ↓
  33         SUBA    GR5,NLEN        ; ↓
  34 MUL10   CPA     GR5,=1          ; ループ先頭。GR1 <- 10 ** GR5
  35         JZE     NEXT            ; (GR5 = 1)の場合、ループ脱出
  36         JMI     NEXT            ; ↓
  37         CALL    MULL            ; MULLを呼び出し、GR0 <- GR1 * GR2
  38         JOV     FIN             ; ↓ オーバーフロー時は、プログラム終端へジャンプ
  39         LD      GR1,GR0         ; GR1 <- GR0
  40         LAD     GR5,-1,GR5      ; GR5 <- GR5 -1
  41         JUMP    MUL10           ; ループ終端へジャンプ
  42 NEXT    LD      GR5,NLEN        ; GR5 <- NLEN。復元
  43         ADDL    GR4,GR1         ; GR4 <- GR4 + GR1
  44         JOV     FIN             ; ↓
  45         LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  46         JUMP    STOL            ; ループ終端
  47 NAN     LAD     GR2,#FFFF       ; GR2 <- #FFFF
  48         JUMP    FIN             ; FINへジャンプ
  49 CP      LD      GR1,GR4         ; GR0 <- GR4
  50         LD      GR0,LEN         ; GR0 <- LEN
  51         JUMP    FIN             ; プログラム終端へジャンプ
  52 LENOV   LAD     GR0,#FFFF       ; 文字列が最大長より大きい場合、GR0 <- #FFFF
  53         SRA     GR0,1           ; ↓ オーバーフロー発生
  54 FIN     POP     GR5
  55         POP     GR4
  56         RET
  57 ZERO    DC      '0'
  58 NINE    DC      '9'
  59 MAXLEN  DC      5               ; 文字列の最大長
  60 STR     DS      1
  61 LEN     DS      1
  62 NLEN    DS      1
  63         END
  64 ;;; 0〜65535の範囲にある正数のかけ算（筆算方式）を行う
  65 ;;; 入力 GR1:被乗数 GR2:乗数
  66 ;;; 出力 GR0:積の下位WORD GR3:積の上位WORD
  67 ;;; 積が65535より大きい場合は、オーバーフロー
  68 MULL    START
  69         PUSH    0,GR4
  70         PUSH    0,GR5
  71         XOR     GR0,GR0         ; 積
  72         XOR     GR3,GR3         ; 上位word
  73         XOR     GR5,GR5         ; 上位wordの一時値
  74         AND     GR1,GR1         ; (GR1 = 0)の場合、終了
  75         JZE     CHKOV           ; ↓
  76         AND     GR2,GR2         ; (GR2 = 0)の場合、終了
  77         JZE     CHKOV           ; ↓
  78         LAD     GR4,1           ; 対象ビット
  79 LOOP    PUSH    0,GR4           ; ループ先頭。GR2のビット中でGR4が示すビットが0の場合、NEXTへジャンプ
  80         AND     GR4,GR2         ; ↓
  81         POP     GR4             ; ↓
  82         JZE     NEXT1           ; ↓
  83         ADDL    GR3,GR5         ; GR3 <- GR3 + GR5
  84         ADDL    GR0,GR1         ; GR0 <- GR0 + GR1
  85         JOV     AHB1            ; GR0がオーバーフローした場合、AHB1へジャンプ
  86         JUMP    NEXT1           ; ↓
  87 AHB1    LAD     GR3,1,GR3       ; GR3 <- GR3 + 1
  88 NEXT1   SLL     GR4,1           ; GR4を1回左シフト
  89         JOV     CHKOV           ; ↓
  90         SLL     GR5,1           ; GR5を1回左シフト
  91         CPL     GR4,GR2         ; (GR4 > GR2)の場合、CHKOVへジャンプ
  92         JPL     CHKOV           ; ↓
  93         SLL     GR1,1           ; GR1を1回左シフト
  94         JOV     AHB2            ; GR1がオーバーフローした場合、AHBへジャンプ
  95         JUMP    NEXT2           ; ↓
  96 AHB2    LAD     GR5,1,GR5       ; GR5 <- GR5 + 1
  97 NEXT2   JUMP    LOOP            ; ループ終端
  98 CHKOV   AND     GR3,GR3         ; GR3 = 0の場合、終了
  99         JZE     FIN             ; ↓
 100         LAD     GR4,#FFFF       ; GR3 <> 0の場合、オーバーフロー
 101         SLL     GR4,1           ; ↓
 102 FIN     POP     GR5
 103         POP     GR4
 104         RET
 105         END